Tutorial Belanja komponen

Tutorial › Suhu & Kelembapan

Monitor Suhu Kulkas / Freezer

IBoleh Tim Ichibot di Suhu & Kelembapan NodeMCU ESP8266 V3Mudah±30 menit

ESP-12ED0D1D2D3D43VGD5D6D7D8RXTXG3VA0GVUS3S2S1SCS0SKG3VENRSTGVINVCCDATGNDAdaptor + probe DS18B20

Probe DS18B20 dimasukkan ke freezer, kabel tipisnya lewat karet pintu. Dashboard mencatat suhu terendah dan tertinggi, dan alarm menyala kalau freezer terlalu hangat lebih dari 10 menit, misalnya pintu tidak tertutup rapat atau listrik sempat padam.

Rangkaiannya sama dengan proyek 023. Yang berbeda ada di logikanya. ESP32 menyimpan nilai minimum dan maksimum sejak di-reset. Alarm tidak langsung menyala saat suhu melewati batas, karena membuka pintu sebentar itu wajar. Alarm baru aktif kalau suhu bertahan di atas batas selama 10 menit berturut-turut.

Komponen

KomponenQtyHarga
NodeMCU ESP8266 V3 (Lolin)1Rp42.000
Sensor DS18B20 waterproof 1 m1Rp14.500
Modul adaptor DS18B20 (ada pull-up)1Rp10.000
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 31Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data1Rp11.700
Total (tanpa opsional)Rp70.000
Daftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

DariKeKabel
Adaptor + probe DS18B20 VCC→3Vmerah
Adaptor + probe DS18B20 DAT→D2 GPIO4kuning
Adaptor + probe DS18B20 GND→Ghitam

Langkah 2: Siapkan dashboard Klenik

Suhu Freezerichibot/budi1234/p029/suhu
-3010-17.5°C
0 detik lalu
Alarmichibot/budi1234/p029/alarm
HANGAT!
0 detik lalu
Terendahichibot/budi1234/p029/min
-30 – 10-19.2°C
0 detik lalu
Tertinggiichibot/budi1234/p029/max
-30 – 10-12.4°C
0 detik lalu
Batas Hangatichibot/budi1234/p029/batas
-10°C-10 of 8°C
0 detik lalu
Ulang Min/Maxichibot/budi1234/p029/ulang
Ulang
Belum pernah ditekan

Cara cepat: unduh p029.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

WidgetTopicSetting
Gauge
Suhu Freezer		ichibot/KODE/p029/suhu-30–10 °C
Indikator Boolean
Alarm		ichibot/KODE/p029/alarmON = 1 “HANGAT!”, OFF = 0
Gauge
Terendah		ichibot/KODE/p029/min-30–10 °C
Gauge
Tertinggi		ichibot/KODE/p029/max-30–10 °C
Slider Output
Batas Hangat		ichibot/KODE/p029/batas-20–8 °C
Switch
Ulang Min/Max		ichibot/KODE/p029/ulangpayload ON / OFF

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), OneWire, DallasTemperature. Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p029.inoUnduh .ino
// Proyek 029 - Monitor Suhu Kulkas / Freezer
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <OneWire.h>
#include <DallasTemperature.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_BATAS = "ichibot/budi1234/p029/batas";
const char* TOPIK_ULANG = "ichibot/budi1234/p029/ulang";
const char* TOPIK_SUHU  = "ichibot/budi1234/p029/suhu";
const char* TOPIK_MIN   = "ichibot/budi1234/p029/min";
const char* TOPIK_MAX   = "ichibot/budi1234/p029/max";
const char* TOPIK_ALARM = "ichibot/budi1234/p029/alarm";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
OneWire kabelData(D2);
DallasTemperature sensor(&kabelData);
float batas = -10.0;                  // freezer dianggap bermasalah di atas suhu ini
float terendah = 99, tertinggi = -99;
unsigned long terakhir = 0, panasSejak = 0;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t, p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_BATAS) batas = p.toFloat();
  else if (topik == TOPIK_ULANG && p == "ON") { terendah = 99; tertinggi = -99; }
}

void langganan() {
  mqtt.subscribe(TOPIK_BATAS);
  mqtt.subscribe(TOPIK_ULANG);
}


sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  sensor.begin();
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (millis() - terakhir < 10000) return;
  terakhir = millis();

  sensor.requestTemperatures();
  float suhu = sensor.getTempCByIndex(0);
  if (suhu == DEVICE_DISCONNECTED_C) return;
  terendah = min(terendah, suhu);
  tertinggi = max(tertinggi, suhu);

  // alarm hanya kalau di atas batas lebih dari 10 menit (pintu dibuka sebentar itu wajar)
  if (suhu > batas) { if (!panasSejak) panasSejak = millis(); }
  else panasSejak = 0;
  bool alarm = panasSejak && millis() - panasSejak > 600000UL;

  mqtt.publish(TOPIK_SUHU, String(suhu, 1).c_str());
  mqtt.publish(TOPIK_MIN, String(terendah, 1).c_str());
  mqtt.publish(TOPIK_MAX, String(tertinggi, 1).c_str());
  mqtt.publish(TOPIK_ALARM, alarm ? "1" : "0", true);
}

Langkah 4: Pahami kodenya

  1. Nilai awal 99 dan -99 sengaja dibuat ekstrem, supaya pembacaan pertama langsung menggantikannya.
  2. 600.000 ms = 10 menit. Untuk kulkas biasa (bukan freezer), batas 8 °C dan tunda 15 menit lebih masuk akal.
  3. Suhu freezer berubah pelan, jadi cukup dibaca tiap 10 detik.