Kipas menyala sendiri saat ruangan panas dan mati saat sudah sejuk. Dari HP kamu mengatur suhu nyalanya, atau mematikan mode otomatis lalu menyalakan kipas manual.

Polanya sama dengan penyiram tanaman (061): sensor, ambang, dan relay. Kipas nyala di suhuNyala dan baru mati 1 °C di bawahnya. Jarak 1 °C ini (histeresis) mencegah kipas nyala-mati terus saat suhu bergoyang di sekitar ambang. Kipas blower 5V diberi daya dari 3 baterai AA lewat kontak relay, supaya arus motornya tidak mengganggu ESP32.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Modul sensor DHT11	1	Rp12.000
Modul relay 1 channel 5V	1	Rp17.000
Kipas blower 5V 5015	1	Rp20.000
Holder baterai 3×AA + kabelbaterai AA dibeli terpisah	1	Rp6.000
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 6	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp133.500

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
DHT11 VCC	→	3V3	merah
DHT11 DATA	→	D4 GPIO4	kuning
DHT11 GND	→	GND	hitam
Relay 1 ch 5V (jumper H) DC+	→	VIN	oranye
Relay 1 ch 5V (jumper H) DC−	→	GND	hitam
Relay 1 ch 5V (jumper H) IN	→	D26 GPIO26	biru
Baterai 3×AA (4,5V) +	→	Relay 1 ch 5V (jumper H) COM	merah
Relay 1 ch 5V (jumper H) NO	→	Kipas blower 5V +	merah
Kipas blower 5V −	→	Baterai 3×AA (4,5V) −	hitam

Langkah 2: Siapkan dashboard Klenik

Suhu Ruanganichibot/budi1234/p028/suhu

0 detik lalu

Kipasichibot/budi1234/p028/kipas/status

BERPUTAR

0 detik lalu

Mode Otomatisichibot/budi1234/p028/otomatis

Otomatis

0 detik lalu

Kipas Manualichibot/budi1234/p028/kipas

Kipas

Belum pernah ditekan

Suhu Nyalaichibot/budi1234/p028/batas

30°C30 of 40°C

0 detik lalu

Cara cepat: unduh p028.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Gauge Suhu Ruangan	`ichibot/KODE/p028/suhu`	0–50 °C
Indikator Boolean Kipas	`ichibot/KODE/p028/kipas/status`	ON = `1` “BERPUTAR”, OFF = `0`
Switch Mode Otomatis	`ichibot/KODE/p028/otomatis`	payload ON / OFF
Switch Kipas Manual	`ichibot/KODE/p028/kipas`	payload ON / OFF
Slider Output Suhu Nyala	`ichibot/KODE/p028/batas`	25–40 °C

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), DHT sensor library (Adafruit), Adafruit Unified Sensor. Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p028.inoUnduh .ino

// Proyek 028 - Kipas Otomatis Berdasarkan Suhu
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_KIPAS_STATUS = "ichibot/budi1234/p028/kipas/status";
const char* TOPIK_SUHU         = "ichibot/budi1234/p028/suhu";
const char* TOPIK_OTOMATIS     = "ichibot/budi1234/p028/otomatis";
const char* TOPIK_BATAS        = "ichibot/budi1234/p028/batas";
const char* TOPIK_KIPAS        = "ichibot/budi1234/p028/kipas";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
DHT dht(4, DHT11);
const int PIN_RELAY = 26;
float suhuNyala = 30.0;               // kipas nyala di atas ini, mati 1 °C di bawahnya
bool otomatis = true, kipas = false;
unsigned long terakhir = 0;

void atur(bool nyala) {
  kipas = nyala;
  digitalWrite(PIN_RELAY, nyala ? HIGH : LOW);
  mqtt.publish(TOPIK_KIPAS_STATUS, nyala ? "1" : "0", true);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t, p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_OTOMATIS) otomatis = (p == "ON");
  else if (topik == TOPIK_BATAS) suhuNyala = p.toFloat();
  else if (topik == TOPIK_KIPAS && !otomatis) atur(p == "ON");
}

void langganan() {
  mqtt.subscribe(TOPIK_OTOMATIS);
  mqtt.subscribe(TOPIK_BATAS);
  mqtt.subscribe(TOPIK_KIPAS);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(PIN_RELAY, OUTPUT);
  dht.begin();
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (millis() - terakhir < 3000) return;
  terakhir = millis();

  float suhu = dht.readTemperature();
  if (isnan(suhu)) return;
  mqtt.publish(TOPIK_SUHU, String(suhu, 1).c_str());
  if (otomatis) {
    if (!kipas && suhu >= suhuNyala) atur(true);
    else if (kipas && suhu <= suhuNyala - 1.0) atur(false);
  }
}

// Proyek 028 - Kipas Otomatis Berdasarkan Suhu
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_KIPAS_STATUS = "ichibot/budi1234/p028/kipas/status";
const char* TOPIK_SUHU         = "ichibot/budi1234/p028/suhu";
const char* TOPIK_OTOMATIS     = "ichibot/budi1234/p028/otomatis";
const char* TOPIK_BATAS        = "ichibot/budi1234/p028/batas";
const char* TOPIK_KIPAS        = "ichibot/budi1234/p028/kipas";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
DHT dht(4, DHT11);
const int PIN_RELAY = 26;
float suhuNyala = 30.0;               // kipas nyala di atas ini, mati 1 °C di bawahnya
bool otomatis = true, kipas = false;
unsigned long terakhir = 0;

void atur(bool nyala) {
  kipas = nyala;
  digitalWrite(PIN_RELAY, nyala ? HIGH : LOW);
  mqtt.publish(TOPIK_KIPAS_STATUS, nyala ? "1" : "0", true);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t, p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_OTOMATIS) otomatis = (p == "ON");
  else if (topik == TOPIK_BATAS) suhuNyala = p.toFloat();
  else if (topik == TOPIK_KIPAS && !otomatis) atur(p == "ON");
}

void langganan() {
  mqtt.subscribe(TOPIK_OTOMATIS);
  mqtt.subscribe(TOPIK_BATAS);
  mqtt.subscribe(TOPIK_KIPAS);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(PIN_RELAY, OUTPUT);
  dht.begin();
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (millis() - terakhir < 3000) return;
  terakhir = millis();

float suhu = dht.readTemperature();
  if (isnan(suhu)) return;
  mqtt.publish(TOPIK_SUHU, String(suhu, 1).c_str());
  if (otomatis) {
    if (!kipas && suhu >= suhuNyala) atur(true);
    else if (kipas && suhu <= suhuNyala - 1.0) atur(false);
  }
}

Langkah 4: Pahami kodenya

Kipas dinyalakan hanya kalau sedang mati dan suhu sudah mencapai ambang. Relay tidak diperintah ulang terus-menerus.
Histeresis 1 °C. Untuk ruangan besar yang suhunya berubah pelan, jarak ini bisa diperkecil.
Perintah manual hanya dituruti saat mode otomatis mati, seperti di proyek 061.