Versi lebih teliti dari proyek 021. DHT22 membaca suhu sampai 0,1 °C dan kelembapan 0-100% dengan galat lebih kecil. Ada tambahan titik embun: suhu ketika udara mulai mengembun, berguna untuk ruang penyimpanan dan gudang.

Kabel dan kodenya hampir sama dengan DHT11. Perbedaannya, DHT22 lebih teliti (±0,5 °C, ±2-5 %RH) dan rentangnya lebih lebar (-40 sampai 80 °C). Titik embun dihitung dari suhu dan kelembapan dengan rumus Magnus. Kalau suhu dinding atau barang turun sampai titik embun, permukaannya akan basah. Ini sebabnya botol dingin berembun dan gudang lembap berjamur.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Sensor DHT22 (AM2302) + kabel	1	Rp32.000
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp110.500

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
DHT22 (AM2302) VCC	→	3V3	merah
DHT22 (AM2302) DATA	→	D4 GPIO4	kuning
DHT22 (AM2302) GND	→	GND	hitam

Langkah 2: Siapkan dashboard Klenik

Suhuichibot/budi1234/p022/suhu

0 detik lalu

Kelembapanichibot/budi1234/p022/lembap

0 detik lalu

Titik Embunichibot/budi1234/p022/embun

0 detik lalu

Cara cepat: unduh p022.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Gauge Suhu	`ichibot/KODE/p022/suhu`	0–50 °C
Gauge Kelembapan	`ichibot/KODE/p022/lembap`	0–100 %
Gauge Titik Embun	`ichibot/KODE/p022/embun`	0–40 °C

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), DHT sensor library (Adafruit), Adafruit Unified Sensor. Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p022.inoUnduh .ino

// Proyek 022 - Suhu Akurat dengan DHT22
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>
#include <math.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_SUHU   = "ichibot/budi1234/p022/suhu";
const char* TOPIK_LEMBAP = "ichibot/budi1234/p022/lembap";
const char* TOPIK_EMBUN  = "ichibot/budi1234/p022/embun";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
DHT dht(4, DHT22);                    // DATA di GPIO4
unsigned long terakhir = 0;

float titikEmbun(float t, float rh) { // rumus Magnus
  float g = log(rh / 100.0) + 17.62 * t / (243.12 + t);
  return 243.12 * g / (17.62 - g);
}

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  dht.begin();
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (millis() - terakhir < 5000) return;
  terakhir = millis();

  float suhu = dht.readTemperature();
  float lembap = dht.readHumidity();
  if (isnan(suhu) || isnan(lembap)) {
    Serial.println("DHT22 tidak terbaca, cek kabel DATA");
    return;
  }
  mqtt.publish(TOPIK_SUHU, String(suhu, 1).c_str());
  mqtt.publish(TOPIK_LEMBAP, String(lembap, 1).c_str());
  mqtt.publish(TOPIK_EMBUN, String(titikEmbun(suhu, lembap), 1).c_str());
}

// Proyek 022 - Suhu Akurat dengan DHT22
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>
#include <math.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_SUHU   = "ichibot/budi1234/p022/suhu";
const char* TOPIK_LEMBAP = "ichibot/budi1234/p022/lembap";
const char* TOPIK_EMBUN  = "ichibot/budi1234/p022/embun";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
DHT dht(4, DHT22);                    // DATA di GPIO4
unsigned long terakhir = 0;

float titikEmbun(float t, float rh) { // rumus Magnus
  float g = log(rh / 100.0) + 17.62 * t / (243.12 + t);
  return 243.12 * g / (17.62 - g);
}

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  dht.begin();
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (millis() - terakhir < 5000) return;
  terakhir = millis();

float suhu = dht.readTemperature();
  float lembap = dht.readHumidity();
  if (isnan(suhu) || isnan(lembap)) {
    Serial.println("DHT22 tidak terbaca, cek kabel DATA");
    return;
  }
  mqtt.publish(TOPIK_SUHU, String(suhu, 1).c_str());
  mqtt.publish(TOPIK_LEMBAP, String(lembap, 1).c_str());
  mqtt.publish(TOPIK_EMBUN, String(titikEmbun(suhu, lembap), 1).c_str());
}

Langkah 4: Pahami kodenya

Satu-satunya perbedaan dengan proyek 021 di bagian sensor: tipe DHT22.
Rumus Magnus dengan konstanta 17,62 dan 243,12 °C, cukup tepat untuk suhu ruangan (galat di bawah 0,5 °C).
Kelembapan dikirim dengan 1 angka desimal karena DHT22 memang cukup teliti untuk itu.