Monitor Suhu & Kelembapan Kamar

// Proyek 021 - Monitor Suhu & Kelembapan Kamar
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_SUHU   = "ichibot/budi1234/p021/suhu";
const char* TOPIK_LEMBAP = "ichibot/budi1234/p021/lembap";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
DHT dht(4, DHT11);                    // DATA di GPIO4
const unsigned long JEDA = 5000;      // kirim tiap 5 detik
unsigned long terakhir = 0;

void langganan() {}                   // proyek ini hanya mengirim, tidak menerima perintah

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  dht.begin();
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (millis() - terakhir < JEDA) return;
  terakhir = millis();

  float suhu   = dht.readTemperature();
  float lembap = dht.readHumidity();
  if (isnan(suhu) || isnan(lembap)) {
    Serial.println("DHT11 tidak terbaca, cek kabel DATA");
    return;
  }
  mqtt.publish(TOPIK_SUHU, String(suhu, 1).c_str());
  mqtt.publish(TOPIK_LEMBAP, String(lembap, 0).c_str());
  Serial.printf("Suhu %.1f C, lembap %.0f %%\n", suhu, lembap);
}