Tombol panik: sekali ditekan, status DARURAT terkunci di dashboard dan LED merah berkedip. Status ini tidak hilang walaupun tombol dilepas, dan hanya bisa dibatalkan dari HP oleh orang yang menanganinya.

Status darurat disimpan di variabel darurat dan dikirim dengan retain, sehingga siapa pun yang membuka dashboard belakangan tetap melihatnya. Tombol harus ditahan 0,3 detik supaya tidak terpicu karena tersenggol. Reset hanya bisa dari switch di Klenik. Ini disengaja: tombol darurat yang bisa dimatikan di tempat kejadian mudah dimatikan sebelum ada yang tahu.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
Push button 6×6 mm (isi 10)isi 10, terpakai 1	1	Rp4.750
LED 5 mm merah (isi 10)isi 10, terpakai 1	1	Rp2.500
Resistor 330 Ω (isi 10)isi 10, terpakai 1	1	Rp1.800
Breadboard mini 170 titik	1	Rp4.875
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 4	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp59.425

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Push button 6×6 mm 1	→	D5 GPIO14	biru
Push button 6×6 mm 2	→	G	hitam
LED merah + resistor 330 Ω +	→	D1 GPIO5	kuning
LED merah + resistor 330 Ω −	→	G	hitam

Langkah 2: Siapkan dashboard Klenik

Status Daruratichibot/budi1234/p018/status

DARURAT

0 detik lalu

Reset Daruratichibot/budi1234/p018/reset

Reset

Belum pernah ditekan

Kejadianichibot/budi1234/p018/log

DARURAT! Tombol ditekan

Darurat di-reset dari dashboard

0 detik lalu

Cara cepat: unduh p018.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Indikator Boolean Status Darurat	`ichibot/KODE/p018/status`	ON = `1` “DARURAT”, OFF = `0`
Switch Reset Darurat	`ichibot/KODE/p018/reset`	payload ON / OFF
Text Log Kejadian	`ichibot/KODE/p018/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p018.inoUnduh .ino

// Proyek 018 - Tombol Darurat dengan Status Terkunci
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_STATUS = "ichibot/budi1234/p018/status";
const char* TOPIK_LOG    = "ichibot/budi1234/p018/log";
const char* TOPIK_RESET  = "ichibot/budi1234/p018/reset";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int TOMBOL = D5, LED = D1;
bool darurat = false;                 // terkunci sampai di-reset dari HP
unsigned long ditekan = 0;

void kirim(const char* pesan) {
  digitalWrite(LED, darurat);
  mqtt.publish(TOPIK_STATUS, darurat ? "1" : "0", true);
  mqtt.publish(TOPIK_LOG, pesan);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (p == "ON" && darurat) {
    darurat = false;
    kirim("Darurat di-reset dari dashboard");
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_RESET);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(TOMBOL, INPUT_PULLUP);
  pinMode(LED, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (digitalRead(TOMBOL) == LOW) {
    if (!ditekan) ditekan = millis();
    if (!darurat && millis() - ditekan > 300) {   // tahan 0,3 detik: cegah tersenggol
      darurat = true;
      kirim("DARURAT! Tombol ditekan");
    }
  } else {
    ditekan = 0;
  }
  if (darurat) digitalWrite(LED, (millis() / 250) % 2);   // LED berkedip cepat
}

// Proyek 018 - Tombol Darurat dengan Status Terkunci
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_STATUS = "ichibot/budi1234/p018/status";
const char* TOPIK_LOG    = "ichibot/budi1234/p018/log";
const char* TOPIK_RESET  = "ichibot/budi1234/p018/reset";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int TOMBOL = D5, LED = D1;
bool darurat = false;                 // terkunci sampai di-reset dari HP
unsigned long ditekan = 0;

void kirim(const char* pesan) {
  digitalWrite(LED, darurat);
  mqtt.publish(TOPIK_STATUS, darurat ? "1" : "0", true);
  mqtt.publish(TOPIK_LOG, pesan);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (p == "ON" && darurat) {
    darurat = false;
    kirim("Darurat di-reset dari dashboard");
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_RESET);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(TOMBOL, INPUT_PULLUP);
  pinMode(LED, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

if (digitalRead(TOMBOL) == LOW) {
    if (!ditekan) ditekan = millis();
    if (!darurat && millis() - ditekan > 300) {   // tahan 0,3 detik: cegah tersenggol
      darurat = true;
      kirim("DARURAT! Tombol ditekan");
    }
  } else {
    ditekan = 0;
  }
  if (darurat) digitalWrite(LED, (millis() / 250) % 2);   // LED berkedip cepat
}

Langkah 4: Pahami kodenya

Status yang "mengunci". Setelah jadi true, hanya pesan reset dari HP yang bisa mengembalikannya.
Tombol harus ditahan lebih dari 0,3 detik. Sentuhan sekilas atau tersenggol tidak memicu alarm.
Reset hanya bereaksi saat switch dinyalakan dan memang sedang darurat. Setelah reset, matikan lagi switch-nya supaya siap dipakai lain kali.
LED berkedip 2 kali per detik selama darurat, sebagai tanda di lokasi bahwa panggilan sudah terkirim.