Joystick seperti di stik PS dibaca ESP32: posisi X dan Y tampil sebagai dua gauge, arah (atas, bawah, kiri, kanan) tercatat di log. Ini dasar untuk remote robot atau kamera putar.

Modul joystick berisi dua potensiometer (sumbu X dan Y) dan satu tombol tekan. ESP32 membaca keduanya lewat pin analog 34 dan 35 (0-4095), lalu mengubahnya menjadi -100 sampai 100. Joystick murah jarang kembali tepat ke tengah, jadi angka kecil (di bawah 12) dianggap 0. Arah ditentukan oleh sumbu yang lebih jauh dari tengah. Arah hanya dikirim kalau berubah, supaya log tidak penuh.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Modul joystick XY	1	Rp9.700
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 5	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp88.200

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Modul joystick GND	→	GND	hitam
Modul joystick +5V	→	3V3	merah
Modul joystick VRx	→	D34 GPIO34	kuning
Modul joystick VRy	→	D35 GPIO35	hijau
Modul joystick SW	→	D32 GPIO32	biru

Langkah 2: Siapkan dashboard Klenik

Sumbu Xichibot/budi1234/p017/x

0 detik lalu

Sumbu Yichibot/budi1234/p017/y

0 detik lalu

Tombol Stikichibot/budi1234/p017/tekan

DITEKAN

0 detik lalu

Arahichibot/budi1234/p017/arah

KANAN

TENGAH

ATAS

KIRI

0 detik lalu

Cara cepat: unduh p017.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Gauge Sumbu X	`ichibot/KODE/p017/x`	-100–100
Gauge Sumbu Y	`ichibot/KODE/p017/y`	-100–100
Indikator Boolean Tombol Stik	`ichibot/KODE/p017/tekan`	ON = `1` “DITEKAN”, OFF = `0`
Text Log Arah	`ichibot/KODE/p017/arah`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p017.inoUnduh .ino

// Proyek 017 - Joystick Kirim Arah ke Dashboard
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_X     = "ichibot/budi1234/p017/x";
const char* TOPIK_Y     = "ichibot/budi1234/p017/y";
const char* TOPIK_TEKAN = "ichibot/budi1234/p017/tekan";
const char* TOPIK_ARAH  = "ichibot/budi1234/p017/arah";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int VRX = 34, VRY = 35, SW = 32;
String arahTadi = "";
unsigned long terakhir = 0;

int skala(int mentah) {               // 0-4095 -> -100..100, tengah ±0
  int v = map(mentah, 0, 4095, -100, 100);
  return abs(v) < 12 ? 0 : v;         // zona mati: joystick murah jarang tepat 0
}

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(SW, INPUT_PULLUP);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (millis() - terakhir < 150) return;
  terakhir = millis();

  int x = skala(analogRead(VRX));
  int y = skala(analogRead(VRY));
  String arah = "TENGAH";
  if (abs(x) > abs(y)) arah = x > 0 ? "KANAN" : "KIRI";
  else if (y != 0) arah = y > 0 ? "BAWAH" : "ATAS";

  mqtt.publish(TOPIK_X, String(x).c_str());
  mqtt.publish(TOPIK_Y, String(y).c_str());
  mqtt.publish(TOPIK_TEKAN, digitalRead(SW) == LOW ? "1" : "0");
  if (arah != arahTadi) {
    arahTadi = arah;
    mqtt.publish(TOPIK_ARAH, arah.c_str());
  }
}

// Proyek 017 - Joystick Kirim Arah ke Dashboard
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_X     = "ichibot/budi1234/p017/x";
const char* TOPIK_Y     = "ichibot/budi1234/p017/y";
const char* TOPIK_TEKAN = "ichibot/budi1234/p017/tekan";
const char* TOPIK_ARAH  = "ichibot/budi1234/p017/arah";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int VRX = 34, VRY = 35, SW = 32;
String arahTadi = "";
unsigned long terakhir = 0;

int skala(int mentah) {               // 0-4095 -> -100..100, tengah ±0
  int v = map(mentah, 0, 4095, -100, 100);
  return abs(v) < 12 ? 0 : v;         // zona mati: joystick murah jarang tepat 0
}

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(SW, INPUT_PULLUP);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (millis() - terakhir < 150) return;
  terakhir = millis();

int x = skala(analogRead(VRX));
  int y = skala(analogRead(VRY));
  String arah = "TENGAH";
  if (abs(x) > abs(y)) arah = x > 0 ? "KANAN" : "KIRI";
  else if (y != 0) arah = y > 0 ? "BAWAH" : "ATAS";

mqtt.publish(TOPIK_X, String(x).c_str());
  mqtt.publish(TOPIK_Y, String(y).c_str());
  mqtt.publish(TOPIK_TEKAN, digitalRead(SW) == LOW ? "1" : "0");
  if (arah != arahTadi) {
    arahTadi = arah;
    mqtt.publish(TOPIK_ARAH, arah.c_str());
  }
}

Langkah 4: Pahami kodenya

GPIO34 dan 35 adalah pin input saja (ADC1), cocok untuk analog dan tetap bisa dibaca saat WiFi aktif.
Zona mati. Tanpa ini, joystick yang dilepas bisa terbaca 5 atau -8 dan arah berkedip-kedip antara TENGAH dan lainnya.
Sumbu yang paling jauh dari tengah menentukan arah. Arah diagonal dianggap ke sumbu yang lebih dominan.
Arah hanya dikirim saat berubah. X dan Y tetap dikirim tiap 150 ms supaya gauge bergerak halus.