Geser slider 0-100% di HP, terang LED ikut berubah halus. Dasarnya sama dengan dimmer lampu dan pengatur kecepatan kipas.

Pin digital cuma bisa HIGH atau LOW. Untuk membuat LED setengah terang, NodeMCU menyalakan dan mematikannya sangat cepat (±1000 kali per detik). Ini disebut PWM. Makin lama porsi "nyala" dalam tiap siklus, makin terang LED terlihat. analogWrite(pin, 0-255) mengatur porsi itu. Persen dari slider diubah ke 0-255 dengan map().

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
LED 5 mm kuning superbright (isi 10)isi 10, terpakai 1	1	Rp2.850
Resistor 330 Ω (isi 10)isi 10, terpakai 1	1	Rp1.800
Breadboard mini 170 titik	1	Rp4.875
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 2	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp55.025

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
LED kuning + resistor 330 Ω +	→	D1 GPIO5	kuning
LED kuning + resistor 330 Ω −	→	G	hitam

Langkah 2: Siapkan dashboard Klenik

Terang LEDichibot/budi1234/p003/terang

70%70 of 100%

0 detik lalu

Terang Sekarangichibot/budi1234/p003/terang/status

0 detik lalu

Cara cepat: unduh p003.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Slider Output Terang LED	`ichibot/KODE/p003/terang`	0–100 %
Gauge Terang Sekarang	`ichibot/KODE/p003/terang/status`	0–100 %

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p003.inoUnduh .ino

// Proyek 003 - Atur Terang LED (PWM) dari HP
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_TERANG_STATUS = "ichibot/budi1234/p003/terang/status";
const char* TOPIK_TERANG        = "ichibot/budi1234/p003/terang";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int LED = D1;                   // GPIO5, mendukung PWM

void atur(int persen) {
  persen = constrain(persen, 0, 100);
  analogWrite(LED, map(persen, 0, 100, 0, 255));
  mqtt.publish(TOPIK_TERANG_STATUS, String(persen).c_str(), true);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  atur(p.toInt());
  Serial.println("Terang " + p + "%");
}

void langganan() {
  mqtt.subscribe(TOPIK_TERANG);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(LED, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
}

// Proyek 003 - Atur Terang LED (PWM) dari HP
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_TERANG_STATUS = "ichibot/budi1234/p003/terang/status";
const char* TOPIK_TERANG        = "ichibot/budi1234/p003/terang";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int LED = D1;                   // GPIO5, mendukung PWM

void atur(int persen) {
  persen = constrain(persen, 0, 100);
  analogWrite(LED, map(persen, 0, 100, 0, 255));
  mqtt.publish(TOPIK_TERANG_STATUS, String(persen).c_str(), true);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  atur(p.toInt());
  Serial.println("Terang " + p + "%");
}

void langganan() {
  mqtt.subscribe(TOPIK_TERANG);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(LED, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
}

Langkah 4: Pahami kodenya

map() mengubah 0-100 menjadi 0-255, rentang PWM bawaan ESP8266 core 3.x. 0 = mati, 255 = terang penuh.
Nilai yang benar-benar dipakai dikirim balik ke gauge. Dari HP kamu bisa memastikan perintah sudah sampai, tanpa melihat LED-nya.
toInt() mengubah teks "70" dari slider menjadi angka 70. Teks yang bukan angka menjadi 0, jadi LED mati, bukan error.