LED berkedip terus, dan kecepatannya kamu atur dari slider di HP: 50 ms sampai 2 detik. Satu switch lagi untuk menghentikan kedipnya.

Kedip dibuat dengan millis(), bukan delay(). NodeMCU mencatat kapan terakhir LED dibalik, lalu membaliknya lagi kalau sudah lewat jeda milidetik. Karena tidak ada delay(), loop() tetap berputar cepat dan perintah dari slider langsung terasa. Slider Klenik mengirim angka biasa ke topic .../p002/jeda saat dilepas.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
LED 5 mm merah (isi 10)isi 10, terpakai 1	1	Rp2.500
Resistor 330 Ω (isi 10)isi 10, terpakai 1	1	Rp1.800
Breadboard mini 170 titik	1	Rp4.875
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 2	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp54.675

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
LED merah + resistor 330 Ω +	→	D1 GPIO5	kuning
LED merah + resistor 330 Ω −	→	G	hitam

Langkah 2: Siapkan dashboard Klenik

Kedipichibot/budi1234/p002/kedip

Kedip

0 detik lalu

Jeda Kedipichibot/budi1234/p002/jeda

500ms500 of 2000ms

0 detik lalu

Cara cepat: unduh p002.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Switch Kedip	`ichibot/KODE/p002/kedip`	payload ON / OFF
Slider Output Jeda Kedip	`ichibot/KODE/p002/jeda`	50–2000 ms

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p002.inoUnduh .ino

// Proyek 002 - LED Kedip dengan Kecepatan dari Slider
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_KEDIP = "ichibot/budi1234/p002/kedip";
const char* TOPIK_JEDA  = "ichibot/budi1234/p002/jeda";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int LED = D1;                   // GPIO5
bool kedip = true;
int jeda = 500;                       // ms antara nyala dan mati
unsigned long terakhir = 0;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t, p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_KEDIP) kedip = (p == "ON");
  else if (topik == TOPIK_JEDA) jeda = constrain(p.toInt(), 50, 2000);
  if (!kedip) digitalWrite(LED, LOW);
  Serial.println(topik + " = " + p);
}

void langganan() {
  mqtt.subscribe(TOPIK_KEDIP);
  mqtt.subscribe(TOPIK_JEDA);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(LED, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (kedip && millis() - terakhir >= (unsigned long)jeda) {
    terakhir = millis();
    digitalWrite(LED, !digitalRead(LED));
  }
}

// Proyek 002 - LED Kedip dengan Kecepatan dari Slider
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_KEDIP = "ichibot/budi1234/p002/kedip";
const char* TOPIK_JEDA  = "ichibot/budi1234/p002/jeda";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int LED = D1;                   // GPIO5
bool kedip = true;
int jeda = 500;                       // ms antara nyala dan mati
unsigned long terakhir = 0;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t, p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_KEDIP) kedip = (p == "ON");
  else if (topik == TOPIK_JEDA) jeda = constrain(p.toInt(), 50, 2000);
  if (!kedip) digitalWrite(LED, LOW);
  Serial.println(topik + " = " + p);
}

void langganan() {
  mqtt.subscribe(TOPIK_KEDIP);
  mqtt.subscribe(TOPIK_JEDA);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(LED, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

if (kedip && millis() - terakhir >= (unsigned long)jeda) {
    terakhir = millis();
    digitalWrite(LED, !digitalRead(LED));
  }
}

Langkah 4: Pahami kodenya

Nilai awal sebelum slider digeser: 500 ms nyala, 500 ms mati.
Proyek ini mendengarkan dua topic. t berisi topic lengkap pesan yang masuk, jadi cukup dibandingkan dengan TOPIK_KEDIP dan TOPIK_JEDA untuk tahu pesan datang dari widget mana.
constrain() menjaga angka tetap di 50-2000. Kalau ada yang mengirim angka aneh ke topic ini, LED tidak ikut kacau.
Inti kedip tanpa delay(). digitalWrite(LED, !digitalRead(LED)) membalik keadaan LED: yang nyala jadi mati, yang mati jadi nyala.