7.1PWM: LED redup-terang

Pin digital cuma bisa nyala atau mati. Tapi kalau dinyalakan dan dimatikan sangat cepat, ratusan kali per detik, mata kita melihat rata-ratanya: LED terlihat redup. Teknik ini namanya PWM (pulse width modulation), dan hanya bisa dipakai di pin bertanda ~: 3, 5, 6, 9, 10, 11.

const int LED = 9;

void setup() {
  pinMode(LED, OUTPUT);
}

void loop() {
  for (int terang = 0; terang <= 255; terang++) {1
    analogWrite(LED, terang);2
    delay(5);
  }
  for (int terang = 255; terang >= 0; terang--) {
    analogWrite(LED, terang);
    delay(5);
  }
}

1. 1Nilai PWM berjalan dari 0 sampai 255.
2. 2analogWrite(pin, nilai): 0 berarti selalu mati, 255 selalu nyala, 127 kira-kira separuh waktu nyala.

LED-nya menyala pelan lalu meredup, seperti bernapas. Gabungkan dengan potensiometer dari 6.1 dan kamu punya lampu yang terangnya diatur dengan tangan:

analogWrite(9, map(analogRead(A0), 0, 1023, 0, 255));

7.2Buzzer: nada & melodi

Ada dua jenis buzzer yang bentuknya mirip. Buzzer aktif langsung berbunyi "biiip" begitu diberi listrik. Buzzer pasif diam saja kalau cuma diberi listrik; dia harus digetarkan dengan frekuensi tertentu, dan karena itu bisa memainkan nada. Bab ini memakai buzzer pasif.

const int BUZZER = 8;

void setup() {
  tone(BUZZER, 440, 500);   // 440 Hz selama 0,5 detik
}

void loop() {
}

tone(pin, frekuensi, lama) membunyikan nada. Frekuensi dalam hertz: makin besar, makin tinggi suaranya. noTone(pin) menghentikannya. Untuk memainkan lagu, simpan nada dan lamanya di dua array, lalu putar dengan for seperti di 4.7.

const int BUZZER = 8;

// Twinkle Twinkle Little Star (lagu tradisional)
int nada[] = {262, 262, 392, 392, 440, 440, 392,
              349, 349, 330, 330, 294, 294, 262};
int lama[] = {400, 400, 400, 400, 400, 400, 800,
              400, 400, 400, 400, 400, 400, 800};

void setup() {
  for (int i = 0; i < 14; i++) {
    tone(BUZZER, nada[i], lama[i] * 0.9);1
    delay(lama[i]);
  }
}

void loop() {
}

1. 1Nada dibunyikan 90% dari jatahnya, lalu diam sebentar. Tanpa jeda ini, dua nada yang sama berurutan akan menyatu jadi satu bunyi panjang.

7.3Servo: lengan yang patuh sudut

Motor biasa berputar terus. Servo berbeda: kamu memberi angka sudut, 0 sampai 180 derajat, dan lengannya bergerak ke sudut itu lalu bertahan di sana. Di dalamnya ada motor kecil, roda gigi, dan sensor posisi. Servo dipakai untuk lengan robot, pintu otomatis, atau setir mobil RC.

#include <Servo.h>1

Servo lengan;

void setup() {
  lengan.attach(9);2
}

void loop() {
  lengan.write(0);3
  delay(1000);
  lengan.write(90);
  delay(1000);
  lengan.write(180);
  delay(1000);
}

1. 1Library Servo sudah ikut terpasang bersama Arduino IDE, tidak perlu diunduh.
2. 2Memberi tahu bahwa servo bernama lengan tersambung di pin 9.
3. 3Bergerak ke 0 derajat. Lengannya butuh waktu untuk sampai, jadi beri jeda sebelum perintah berikutnya.

Pasang tuas plastik (yang ikut di bungkus servo) di porosnya supaya gerakannya terlihat. Ganti isi loop() dengan lengan.write(map(analogRead(A0), 0, 1023, 0, 180));, pasang potensiometer seperti 6.1, dan servo akan mengikuti putaran tanganmu.

7.4Relay: menyalakan beban besar

Pin Arduino cuma kuat menyalakan LED. Untuk lampu, pompa air mini, atau kipas, dipakai relay: saklar yang ditekan oleh magnet kecil. Arduino cukup mengalirkan sedikit listrik ke magnetnya, dan "klik", saklar di sisi lain tersambung. Kedua sisi tidak bersentuhan secara listrik, jadi sisi beban boleh memakai sumber listrik lain.

Terminal sekrup hijau di modul relay punya tiga lubang:

• COM (common): kaki bersama, selalu dipakai.
• NO (normally open): tersambung ke COM hanya saat relay aktif. Ini yang dipakai untuk "nyalakan saat diperintah".
• NC (normally closed): kebalikannya, tersambung ke COM saat relay tidak aktif.

const int RELAY = 7;
const bool AKTIF = LOW;1

void setup() {
  pinMode(RELAY, OUTPUT);
  digitalWrite(RELAY, !AKTIF);       // mulai dalam keadaan mati
}

void loop() {
  digitalWrite(RELAY, AKTIF);        // klik: lampu nyala
  delay(2000);
  digitalWrite(RELAY, !AKTIF);       // lampu mati
  delay(2000);
}

1. 1Kebanyakan modul relay murah aktif LOW: relay menyala saat pin IN diberi LOW. Kalau relaymu malah aktif saat HIGH (perhatikan LED kecil di modulnya), ganti baris ini jadi HIGH. Bagian lain program tidak perlu diubah.

7.5Kenapa motor nggak boleh langsung ke pin

Motor DC kecil, seperti yang ada di mainan, butuh arus ratusan miliampere saat berputar dan lebih besar lagi saat mulai bergerak. Satu pin Arduino sebaiknya tidak dibebani lebih dari sekitar 20 mA. Kalau motor dicolok langsung, motornya tidak kuat berputar, dan pinnya bisa rusak.

Solusinya transistor, komponen yang bekerja seperti keran: arus kecil dari pin Arduino ke kaki basis membuka jalan bagi arus besar dari kolektor ke emitor. Arus besarnya diambil dari baterai, bukan dari Arduino.

const int MOTOR = 9;

void setup() {
  pinMode(MOTOR, OUTPUT);
}

void loop() {
  analogWrite(MOTOR, 255);     // kencang
  delay(2000);
  analogWrite(MOTOR, 120);     // pelan
  delay(2000);
  analogWrite(MOTOR, 0);       // berhenti
  delay(2000);
}

Karena pin 9 mendukung PWM, kecepatan motor bisa diatur seperti terang LED di 7.1. Nilai yang terlalu kecil, misalnya di bawah 80, mungkin belum cukup untuk membuat motor mulai berputar.