4.0Rangkaian latihan

Rangkaian ini dipakai di semua contoh Bab 4. Lima LED di pin 3, 4, 5, 6, 7, dan satu tombol di pin 2 seperti di Bab 3.4.

Kali ini resistor dipasang di kaki pendek LED, antara LED dan GND. Hasilnya sama saja: yang penting di jalur dari pin ke GND ada satu resistor. Cara ini menghemat kabel karena resistornya langsung menancap di rel.

void setup() {
  for (int pin = 3; pin <= 7; pin++) pinMode(pin, OUTPUT);
}

void loop() {
  for (int pin = 3; pin <= 7; pin++) digitalWrite(pin, HIGH);
}

Program pendek di atas menyalakan kelima LED sekaligus. Kalau ada yang tidak menyala, cek arah LED dan kabelnya sebelum lanjut. Bentuk for di situ akan dijelaskan di 4.5.

4.1Aturan menulis

Arduino diprogram dengan bahasa C++. Bahasanya ketat: komputer tidak bisa menebak maksudmu kalau ada satu tanda yang salah. Untungnya aturan dasarnya sedikit.

Komentar adalah catatan untuk manusia. Arduino mengabaikannya. Pakai untuk menjelaskan kenapa sebuah baris ada, misalnya // tunggu pantulan tombol reda. Kamu sendiri yang paling berterima kasih saat membuka program itu lagi bulan depan.

Isi di dalam kurung kurawal biasanya ditulis menjorok ke dalam (indentasi). Arduino tidak peduli, tapi matamu akan peduli. Menu Tools › Auto Format (Ctrl + T) merapikan indentasi seluruh program dalam sekali klik.

4.2Variabel & tipe data

Variabel adalah kotak berlabel untuk menyimpan nilai. Setiap kotak punya tiga hal: tipe (jenis isi yang boleh disimpan), nama, dan isinya.

int jumlahKedip = 12;      // tipe, nama, isi awal
float suhu = 28.5;
bool lampuNyala = true;
char huruf = 'A';

jumlahKedip = jumlahKedip + 1;   // isinya sekarang 13

Bilangan berkoma di program ditulis dengan titik, bukan koma: 28.5, bukan 28,5.

Konstanta: variabel yang tidak boleh berubah

Kalau sebuah nilai tidak akan pernah berubah, misalnya nomor pin, tambahkan const di depannya. Kalau tanpa sengaja kamu mengubahnya di tengah program, Verify akan menolak. Nama konstanta biasa ditulis huruf besar semua supaya mudah dibedakan.

const int LED_MERAH = 3;
const int TOMBOL = 2;

Di mana variabel ditulis itu penting

Variabel yang ditulis di luar setup() dan loop() bisa dipakai di mana saja dan isinya bertahan selama papan menyala. Variabel yang ditulis di dalam loop() dibuat ulang setiap putaran, jadi isinya kembali ke awal terus. Itu sebabnya di proyek 3.5, lampuNyala ditulis di luar.

4.3Menghitung & membandingkan

4.4Mengambil keputusan

if menjalankan sekelompok perintah hanya kalau syaratnya benar. else if memberi syarat cadangan, dan else menangkap sisanya. Contoh: lampu yang menyala tergantung berapa kali tombol sudah ditekan.

const int TOMBOL = 2;
int tekan = 0;

void setup() {
  pinMode(TOMBOL, INPUT_PULLUP);
  for (int pin = 3; pin <= 7; pin++) pinMode(pin, OUTPUT);
}

void loop() {
  if (digitalRead(TOMBOL) == LOW) {
    tekan++;
    delay(300);          // satu tekan = satu hitungan
  }

  for (int pin = 3; pin <= 7; pin++) digitalWrite(pin, LOW);

  if (tekan < 3) {1
    digitalWrite(3, HIGH);
  } else if (tekan < 6) {2
    digitalWrite(5, HIGH);
  } else {
    digitalWrite(7, HIGH);
  }
}

1. 1Tiga tekanan pertama (0, 1, 2) menyalakan LED pin 3.
2. 2else if baru diperiksa kalau syarat pertama salah. Jadi syarat tekan < 6 ini sebenarnya berarti "3 sampai 5". Mulai tekanan keenam, else yang jalan.

4.5Mengulang dengan for & while

Menyalakan lima LED satu per satu bisa ditulis sepuluh baris. Dengan for, cukup tiga.

void setup() {
  for (int pin = 3; pin <= 7; pin++) {
    pinMode(pin, OUTPUT);
  }
}

void loop() {
  for (int pin = 3; pin <= 7; pin++) {1
    digitalWrite(pin, HIGH);
    delay(150);
    digitalWrite(pin, LOW);
  }
}

1. 1Isi kurung for ada tiga bagian, dipisah titik koma: mulai dari pin = 3, ulangi selama pin <= 7, dan setiap selesai satu putaran pin++. Jadi isinya dijalankan untuk pin 3, 4, 5, 6, 7, lalu berhenti.

Hasilnya cahaya yang berlari dari kiri ke kanan. Variabel pin di situ hanya hidup di dalam for; di luarnya, nama itu tidak dikenal.

while: ulangi selama syaratnya benar

while dipakai kalau kamu tidak tahu berapa kali harus mengulang, hanya tahu kapan berhenti. Contoh paling berguna: menunggu tombol ditekan.

while (digitalRead(TOMBOL) == HIGH) {
  // diam saja di sini sampai tombol ditekan
}

4.6Bikin fungsi sendiri

setup(), loop(), digitalWrite(), dan delay() semuanya fungsi: sekumpulan perintah yang diberi nama. Kamu bisa membuat fungsimu sendiri untuk pekerjaan yang diulang-ulang.

void kedip(int pin, int kali, int jeda) {1
  for (int i = 0; i < kali; i++) {
    digitalWrite(pin, HIGH);
    delay(jeda);
    digitalWrite(pin, LOW);
    delay(jeda);
  }
}

void setup() {
  for (int pin = 3; pin <= 7; pin++) pinMode(pin, OUTPUT);
}

void loop() {
  kedip(3, 3, 100);2
  kedip(5, 2, 300);
  kedip(7, 1, 800);
}

1. 1void berarti fungsi ini tidak mengembalikan hasil apa pun, cuma mengerjakan sesuatu. Di dalam kurung ada parameter: nilai yang dikirim saat fungsi dipanggil.
2. 2Memanggil fungsi: LED pin 3 berkedip 3 kali cepat. Urutan nilainya harus sama dengan urutan parameter.

Fungsi yang mengembalikan hasil

Ganti void dengan tipe hasilnya, lalu pakai return:

bool tombolDitekan() {
  return digitalRead(2) == LOW;
}

// dipakai seperti ini:
if (tombolDitekan()) { ... }

Nama fungsi seperti tombolDitekan() membuat if-nya bisa dibaca seperti kalimat. Itu alasan utama membuat fungsi: program jadi pendek dan menjelaskan dirinya sendiri.

4.7Array: banyak nilai, satu nama

Rangkaian latihan kebetulan memakai pin berurutan, 3 sampai 7, jadi for bisa langsung menghitung pinnya. Di proyek sungguhan, pin sering tidak berurutan. Array menyimpan beberapa nilai dalam satu nama, berbaris dengan nomor urut.

int led[] = {3, 4, 5, 6, 7};1
int pola[] = {0, 4, 1, 3, 2};2

void setup() {
  for (int i = 0; i < 5; i++) pinMode(led[i], OUTPUT);
}

void loop() {
  for (int i = 0; i < 5; i++) {
    digitalWrite(led[pola[i]], HIGH);
    delay(200);
    digitalWrite(led[pola[i]], LOW);
  }
}

1. 1Isi array diambil dengan nomor urut di dalam kurung siku. Nomornya mulai dari 0: led[0] adalah 3, led[4] adalah 7. Tidak ada led[5].
2. 2Array kedua menyimpan urutan nyala: luar, luar, dalam, dalam, tengah. Mengganti pola cukup mengubah satu baris ini.

4.8Menunggu tanpa membeku

Selama delay(1000) berjalan, Arduino tidak melakukan apa-apa lagi: tombol tidak dibaca, LED lain tidak diurus. Untuk satu LED itu tidak masalah. Untuk dua LED yang berkedip dengan kecepatan berbeda, delay() tidak bisa dipakai.

Solusinya adalah millis(): jam di dalam Arduino yang menghitung milidetik sejak papan menyala. Daripada tidur, Arduino mengecek jam setiap putaran loop(): "sudah waktunya belum?"

unsigned long terakhirA = 0;1
unsigned long terakhirB = 0;
bool nyalaA = false;
bool nyalaB = false;

void setup() {
  pinMode(3, OUTPUT);
  pinMode(7, OUTPUT);
}

void loop() {
  unsigned long sekarang = millis();

  if (sekarang - terakhirA >= 500) {2
    terakhirA = sekarang;
    nyalaA = !nyalaA;
    digitalWrite(3, nyalaA);
  }

  if (sekarang - terakhirB >= 130) {
    terakhirB = sekarang;
    nyalaB = !nyalaB;
    digitalWrite(7, nyalaB);
  }
}

1. 1Waktu disimpan dalam unsigned long, karena dalam beberapa puluh detik angka milidetik sudah melewati batas int.
2. 2"Kalau sudah lewat 500 milidetik sejak terakhir berganti", ganti keadaan LED dan catat waktunya. Bentuk pengurangan sekarang - terakhirA ini sengaja dipakai, karena tetap benar walaupun millis() suatu saat kembali ke nol.

LED pin 3 berkedip pelan, LED pin 7 berkedip cepat, dan keduanya tidak saling mengganggu. Karena loop() tidak pernah tidur, kamu bisa menambahkan pembacaan tombol di dalamnya dan tombol akan langsung terasa responsif.

4.9Membaca pesan error

Setiap programmer, termasuk yang sudah puluhan tahun, melihat pesan error setiap hari. Bedanya cuma satu: mereka membacanya. Pesan error dari Arduino IDE muncul di panel Output saat Verify atau Upload, dan baris yang bermasalah ikut disorot merah di editor.

sketch_oct20a.ino: In function 'void loop()':
sketch_oct20a.ino:6:3: error: expected ';' before 'delay'
Compilation error: expected ';' before 'delay'

Angka 6:3 berarti baris 6, kolom 3. Tapi perhatikan: titik koma yang hilang biasanya ada di akhir baris sebelumnya, karena Arduino baru sadar ada yang kurang saat bertemu perintah berikutnya.