Dua Board Saling Bicara lewat MQTT

// Proyek 150 - Dua Board Saling Bicara lewat MQTT
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
// Pasangannya: NodeMCU yang menjalankan PROYEK 001 (Lampu LED dari HP), dengan KODE yang sama.
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LOG          = "ichibot/budi1234/p150/log";
// topic proyek 001 di NodeMCU teman: KODE-nya harus sama
const char* TOPIK_TEMAN_LED    = "ichibot/budi1234/p001/led";
const char* TOPIK_TEMAN_STATUS = "ichibot/budi1234/p001/status";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int TOMBOL = 27, LED = 25;
bool ledTeman = false, tadi = HIGH;
unsigned long waktuTekan = 0;


void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  ledTeman = (p == "1");              // NodeMCU melaporkan keadaan LED-nya
  digitalWrite(LED, ledTeman);        // LED kita meniru LED di NodeMCU
  mqtt.publish(TOPIK_LOG, ledTeman ? "LED NodeMCU menyala" : "LED NodeMCU mati");
}

void langganan() {
  mqtt.subscribe(TOPIK_TEMAN_STATUS);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(TOMBOL, INPUT_PULLUP);
  pinMode(LED, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  bool sekarang = digitalRead(TOMBOL);
  if (sekarang != tadi && millis() - waktuTekan > 50) {
    waktuTekan = millis();
    tadi = sekarang;
    if (sekarang == LOW) {            // tekan: suruh NodeMCU membalik LED-nya
      mqtt.publish(TOPIK_TEMAN_LED, ledTeman ? "OFF" : "ON");
    }
  }
}