Detak Jantung & SpO2 MAX30100

// Proyek 140 - Detak Jantung & SpO2 MAX30100
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <MAX30100_PulseOximeter.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_JARI = "ichibot/budi1234/p140/jari";
const char* TOPIK_BPM  = "ichibot/budi1234/p140/bpm";
const char* TOPIK_SPO2 = "ichibot/budi1234/p140/spo2";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
PulseOximeter oksimeter;
unsigned long kirimTerakhir = 0;
volatile int detak = 0;

void saatDetak() { detak++; }        // dipanggil pustaka setiap jantung berdetak

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  sambungMQTT();
  if (!oksimeter.begin()) Serial.println("MAX30100 tidak ditemukan, cek SDA/SCL");
  oksimeter.setIRLedCurrent(MAX30100_LED_CURR_7_6MA);
  oksimeter.setOnBeatDetectedCallback(saatDetak);
}

void loop() {
  oksimeter.update();                 // wajib dipanggil sesering mungkin
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (millis() - kirimTerakhir >= 2000) {
    kirimTerakhir = millis();
    float bpm = oksimeter.getHeartRate();
    int spo2 = oksimeter.getSpO2();
    bool adaJari = detak > 0;
    detak = 0;
    mqtt.publish(TOPIK_JARI, adaJari ? "1" : "0");
    if (adaJari) {
      mqtt.publish(TOPIK_BPM, String(bpm, 0).c_str());
      mqtt.publish(TOPIK_SPO2, String(spo2).c_str());
    }
  }
}