Tanpa komponen tambahan sama sekali: NodeMCU dicolok ke adaptor di rumah, dan saat listrik padam Klenik di HP berubah menjadi PADAM. Saat listrik kembali, jamnya tercatat. Cocok untuk memantau rumah yang ditinggal mudik atau freezer di warung.

Kalau NodeMCU mati karena listrik padam, ia tidak bisa mengirim kabar apa pun. Triknya memakai fitur MQTT bernama Last Will (pesan terakhir). Saat tersambung, NodeMCU menitipkan pesan 0 untuk topic listrik ke broker. Kalau koneksi putus tanpa pamit, broker sendiri yang mengirim pesan titipan itu. Broker berada di internet dan tidak ikut padam.

Broker tahu koneksi putus karena NodeMCU berhenti menyapa. setKeepAlive(15) membuat NodeMCU menyapa setiap 15 detik, sehingga broker menyadari kepergiannya dalam ±22 detik. Begitu listrik kembali dan NodeMCU tersambung lagi, 1 dikirim ke topic yang sama dan jam menyalanya dicatat. Router WiFi juga ikut padam, tetapi itu tidak masalah karena yang mengirim kabar adalah broker.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp42.000

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel

Langkah 2: Siapkan dashboard Klenik

Listrik Rumahichibot/budi1234/p128/listrik

MENYALA

0 detik lalu

Riwayat Listrikichibot/budi1234/p128/log

Listrik menyala 27/10 19:42

Listrik menyala 28/10 06:15

0 detik lalu

Cara cepat: unduh p128.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Indikator Boolean Listrik Rumah	`ichibot/KODE/p128/listrik`	ON = `1` “MENYALA”, OFF = `0`
Text Log Riwayat Listrik	`ichibot/KODE/p128/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p128.inoUnduh .ino

// Proyek 128 - Notifikasi Listrik PLN Padam
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LISTRIK = "ichibot/budi1234/p128/listrik";
const char* TOPIK_LOG     = "ichibot/budi1234/p128/log";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
bool sudahLapor = false;

void langganan() {}

void sambungDenganPesanTerakhir() {   // seperti sambungMQTT(), ditambah "last will"
  while (!mqtt.connected()) {
    // kalau koneksi putus tiba-tiba, BROKER yang mengirim "0" ke topic listrik
    if (mqtt.connect(WiFi.macAddress().c_str(), TOPIK_LISTRIK, 1, true, "0")) {
      mqtt.publish(TOPIK_LISTRIK, "1", true);
    } else {
      delay(3000);
    }
  }
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
  mqtt.setKeepAlive(15);              // broker menganggap kita hilang setelah ±22 detik diam
}

void loop() {
  if (!mqtt.connected()) sambungDenganPesanTerakhir();
  mqtt.loop();

  time_t t = time(nullptr);
  if (!sudahLapor && t > 1700000000) {
    sudahLapor = true;                // sekali setiap NodeMCU menyala = listrik baru kembali
    char jam[17];
    strftime(jam, sizeof(jam), "%d/%m %H:%M", localtime(&t));
    mqtt.publish(TOPIK_LOG, (String("Listrik menyala ") + jam).c_str());
  }
}

// Proyek 128 - Notifikasi Listrik PLN Padam
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LISTRIK = "ichibot/budi1234/p128/listrik";
const char* TOPIK_LOG     = "ichibot/budi1234/p128/log";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
bool sudahLapor = false;

void langganan() {}

void sambungDenganPesanTerakhir() {   // seperti sambungMQTT(), ditambah "last will"
  while (!mqtt.connected()) {
    // kalau koneksi putus tiba-tiba, BROKER yang mengirim "0" ke topic listrik
    if (mqtt.connect(WiFi.macAddress().c_str(), TOPIK_LISTRIK, 1, true, "0")) {
      mqtt.publish(TOPIK_LISTRIK, "1", true);
    } else {
      delay(3000);
    }
  }
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
  mqtt.setKeepAlive(15);              // broker menganggap kita hilang setelah ±22 detik diam
}

void loop() {
  if (!mqtt.connected()) sambungDenganPesanTerakhir();
  mqtt.loop();

time_t t = time(nullptr);
  if (!sudahLapor && t > 1700000000) {
    sudahLapor = true;                // sekali setiap NodeMCU menyala = listrik baru kembali
    char jam[17];
    strftime(jam, sizeof(jam), "%d/%m %H:%M", localtime(&t));
    mqtt.publish(TOPIK_LOG, (String("Listrik menyala ") + jam).c_str());
  }
}

Langkah 4: Pahami kodenya

Versi connect() dengan pesan terakhir: topic, QoS 1, retained, dan isi pesannya. Pesan ini disimpan broker dan hanya dikirim kalau kita hilang tanpa pamit.
Interval sapaan ke broker dalam detik. Makin kecil, makin cepat padam terdeteksi.
Begitu jam internet didapat setelah menyala, laporan "Listrik menyala" dikirim sekali.