Sensor inframerah di celah kotak surat atau kotak paket memberi tahu setiap kali ada kiriman masuk, lengkap dengan jamnya. Status ADA KIRIMAN tetap menyala sampai kamu menekan switch Sudah dikosongkan setelah mengambil isinya.

KY-032 dipasang di dalam kotak, menghadap ke celah masuk. Saat surat atau paket lewat, pantulan inframerah membuat OUT menjadi LOW sesaat. Yang dihitung hanya perubahan dari kosong ke ada (ada && !adaTadi), dan selama 3 detik setelahnya sensor diabaikan supaya satu paket yang lewat pelan tidak terhitung dua.

Status ada dan jumlah kiriman dikirim dengan flag retained, sehingga tetap terlihat walaupun dashboard baru dibuka sore hari. Switch Sudah dikosongkan menolkan semuanya.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
Sensor IR KY-032	1	Rp7.500
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp53.000

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Sensor IR KY-032 GND	→	G	hitam
Sensor IR KY-032 +	→	3V	merah
Sensor IR KY-032 OUT	→	D5 GPIO14	biru

Langkah 2: Siapkan dashboard Klenik

Kotak Suratichibot/budi1234/p120/ada

ADA KIRIMAN

0 detik lalu

Jumlah Kirimanichibot/budi1234/p120/jumlah

0 detik lalu

Sudah Dikosongkanichibot/budi1234/p120/kosongkan

Kosong

0 detik lalu

Riwayatichibot/budi1234/p120/log

10:42 Ada kiriman masuk

14:15 Ada kiriman masuk

0 detik lalu

Cara cepat: unduh p120.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Indikator Boolean Kotak Surat	`ichibot/KODE/p120/ada`	ON = `1` “ADA KIRIMAN”, OFF = `0`
Gauge Jumlah Kiriman	`ichibot/KODE/p120/jumlah`	0–10
Switch Sudah Dikosongkan	`ichibot/KODE/p120/kosongkan`	payload ON / OFF
Text Log Riwayat	`ichibot/KODE/p120/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p120.inoUnduh .ino

// Proyek 120 - Kotak Surat Pintar (Ada Paket)
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_JUMLAH    = "ichibot/budi1234/p120/jumlah";
const char* TOPIK_ADA       = "ichibot/budi1234/p120/ada";
const char* TOPIK_KOSONGKAN = "ichibot/budi1234/p120/kosongkan";
const char* TOPIK_LOG       = "ichibot/budi1234/p120/log";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int SENSOR = D5;                // KY-032 OUT: LOW saat ada benda lewat celah
int jumlahKiriman = 0;
bool adaTadi = false;
unsigned long lewatPada = 0;

String jamSekarang() {
  time_t t = time(nullptr);
  char buf[6];
  strftime(buf, sizeof(buf), "%H:%M", localtime(&t));
  return String(buf);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (p == "ON") {                    // kotak sudah dikosongkan
    jumlahKiriman = 0;
    mqtt.publish(TOPIK_JUMLAH, "0", true);
    mqtt.publish(TOPIK_ADA, "0", true);
    mqtt.publish(TOPIK_KOSONGKAN, "OFF");
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_KOSONGKAN);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(SENSOR, INPUT);
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  bool ada = digitalRead(SENSOR) == LOW;
  if (ada && !adaTadi && millis() - lewatPada > 3000) {   // satu kiriman, abaikan 3 detik setelahnya
    lewatPada = millis();
    jumlahKiriman++;
    mqtt.publish(TOPIK_ADA, "1", true);
    mqtt.publish(TOPIK_JUMLAH, String(jumlahKiriman).c_str(), true);
    mqtt.publish(TOPIK_LOG, (jamSekarang() + " Ada kiriman masuk").c_str());
  }
  adaTadi = ada;
}

// Proyek 120 - Kotak Surat Pintar (Ada Paket)
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_JUMLAH    = "ichibot/budi1234/p120/jumlah";
const char* TOPIK_ADA       = "ichibot/budi1234/p120/ada";
const char* TOPIK_KOSONGKAN = "ichibot/budi1234/p120/kosongkan";
const char* TOPIK_LOG       = "ichibot/budi1234/p120/log";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int SENSOR = D5;                // KY-032 OUT: LOW saat ada benda lewat celah
int jumlahKiriman = 0;
bool adaTadi = false;
unsigned long lewatPada = 0;

String jamSekarang() {
  time_t t = time(nullptr);
  char buf[6];
  strftime(buf, sizeof(buf), "%H:%M", localtime(&t));
  return String(buf);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (p == "ON") {                    // kotak sudah dikosongkan
    jumlahKiriman = 0;
    mqtt.publish(TOPIK_JUMLAH, "0", true);
    mqtt.publish(TOPIK_ADA, "0", true);
    mqtt.publish(TOPIK_KOSONGKAN, "OFF");
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_KOSONGKAN);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(SENSOR, INPUT);
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

bool ada = digitalRead(SENSOR) == LOW;
  if (ada && !adaTadi && millis() - lewatPada > 3000) {   // satu kiriman, abaikan 3 detik setelahnya
    lewatPada = millis();
    jumlahKiriman++;
    mqtt.publish(TOPIK_ADA, "1", true);
    mqtt.publish(TOPIK_JUMLAH, String(jumlahKiriman).c_str(), true);
    mqtt.publish(TOPIK_LOG, (jamSekarang() + " Ada kiriman masuk").c_str());
  }
  adaTadi = ada;
}

Langkah 4: Pahami kodenya

Tiga syarat: ada benda, sebelumnya kosong, dan sudah 3 detik sejak kiriman terakhir.
Status ADA KIRIMAN tersimpan di broker (retained) sampai dikosongkan.