Tirai Otomatis Stepper

// Proyek 096 - Tirai Otomatis Stepper
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LOG      = "ichibot/budi1234/p096/log";
const char* TOPIK_OTOMATIS = "ichibot/budi1234/p096/otomatis";
const char* TOPIK_TIRAI    = "ichibot/budi1234/p096/tirai";
const char* TOPIK_TERBUKA  = "ichibot/budi1234/p096/terbuka";
const char* TOPIK_CAHAYA   = "ichibot/budi1234/p096/cahaya";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN[4] = {19, 18, 5, 4};
const int PIN_LDR = 34;
const long LANGKAH_BUKA = 4096L * 5;  // tirai terbuka penuh = 5 putaran motor
const int LDR_TERANG = 1500, LDR_GELAP = 3000;   // histeresis
const uint8_t URUTAN[8] = {0b1000, 0b1100, 0b0100, 0b0110, 0b0010, 0b0011, 0b0001, 0b1001};
long posisi = 0, tujuan = 0;          // 0 = tertutup (posisi saat dinyalakan)
int fase = 0;
bool otomatis = true;
unsigned long langkahTerakhir = 0, cekTerakhir = 0;

void satuLangkah(int arah) {
  fase = (fase + arah + 8) % 8;
  for (int i = 0; i < 4; i++) digitalWrite(PIN[i], (URUTAN[fase] >> (3 - i)) & 1);
  posisi += arah;
}

void aturTirai(bool buka, const char* sebab) {
  long baru = buka ? LANGKAH_BUKA : 0;
  if (baru == tujuan) return;
  tujuan = baru;
  mqtt.publish(TOPIK_LOG, (String(buka ? "Tirai dibuka" : "Tirai ditutup") + " (" + sebab + ")").c_str());
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_OTOMATIS) otomatis = (p == "ON");
  else if (topik == TOPIK_TIRAI) {
    otomatis = false;                 // perintah manual mematikan mode otomatis
    mqtt.publish(TOPIK_OTOMATIS, "OFF", true);
    aturTirai(p == "ON", "manual");
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_OTOMATIS);
  mqtt.subscribe(TOPIK_TIRAI);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  for (int i = 0; i < 4; i++) pinMode(PIN[i], OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (posisi != tujuan) {
    if (micros() - langkahTerakhir >= 1200) {
      langkahTerakhir = micros();
      satuLangkah(tujuan > posisi ? 1 : -1);
      if (posisi == tujuan) {
        for (int i = 0; i < 4; i++) digitalWrite(PIN[i], LOW);
        mqtt.publish(TOPIK_TERBUKA, posisi ? "1" : "0", true);
      }
    }
    return;                           // selama bergerak, fokus ke motor
  }

  if (millis() - cekTerakhir >= 5000) {
    cekTerakhir = millis();
    int ldr = analogRead(PIN_LDR);    // KY-018: makin terang makin kecil
    mqtt.publish(TOPIK_CAHAYA, String(ldr).c_str());
    if (otomatis) {
      if (ldr < LDR_TERANG) aturTirai(true, "pagi");
      else if (ldr > LDR_GELAP) aturTirai(false, "malam");
    }
  }
}