Pompa Isi Tandon Otomatis

// Proyek 066 - Pompa Isi Tandon Otomatis
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_POMPA_STATUS = "ichibot/budi1234/p066/pompa/status";
const char* TOPIK_LOG          = "ichibot/budi1234/p066/log";
const char* TOPIK_OTOMATIS     = "ichibot/budi1234/p066/otomatis";
const char* TOPIK_PENUH        = "ichibot/budi1234/p066/penuh";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PELAMPUNG = 4, RELAY = 26;
const unsigned long JEDA_NYALA = 5UL * 60 * 1000;    // tunggu 5 menit setelah tandon tidak penuh
const unsigned long BATAS_POMPA = 30UL * 60 * 1000;  // pompa maksimal 30 menit sekali jalan
bool otomatis = true, pompa = false, macet = false;
unsigned long tidakPenuhSejak = 0, pompaSejak = 0, kirimTerakhir = 0;

void aturPompa(bool v, const char* sebab) {
  if (v == pompa) return;
  pompa = v;
  digitalWrite(RELAY, v ? HIGH : LOW);
  if (v) pompaSejak = millis();
  mqtt.publish(TOPIK_POMPA_STATUS, v ? "1" : "0", true);
  mqtt.publish(TOPIK_LOG, (String(v ? "Pompa nyala" : "Pompa mati") + " (" + sebab + ")").c_str());
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_OTOMATIS) {
    otomatis = (p == "ON");
    macet = false;                    // menyalakan ulang mode otomatis = reset pengaman
    if (!otomatis) aturPompa(false, "mode manual");
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_OTOMATIS);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(PELAMPUNG, INPUT_PULLUP);
  pinMode(RELAY, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  bool penuh = digitalRead(PELAMPUNG) == LOW;
  if (penuh) tidakPenuhSejak = 0;
  else if (tidakPenuhSejak == 0) tidakPenuhSejak = millis();

  if (otomatis && !macet) {
    if (penuh) {
      aturPompa(false, "tandon penuh");
    } else if (!pompa && millis() - tidakPenuhSejak > JEDA_NYALA) {
      aturPompa(true, "air turun");
    }
    if (pompa && millis() - pompaSejak > BATAS_POMPA) {
      aturPompa(false, "terlalu lama");
      macet = true;
      mqtt.publish(TOPIK_LOG, "CEK POMPA/SUMBER AIR. Matikan lalu nyalakan mode otomatis untuk mencoba lagi");
    }
  }

  if (millis() - kirimTerakhir >= 5000) {
    kirimTerakhir = millis();
    mqtt.publish(TOPIK_PENUH, penuh ? "1" : "0");
  }
}