Atur lama memasak dengan slider, nyalakan switch Mulai, lalu tinggalkan dapur. Sisa waktu terlihat di HP, dan buzzer di dapur berbunyi tit-tit-tit saat waktunya habis.

Saat switch Mulai dinyalakan, NodeMCU mencatat millis() sebagai waktu awal. Selisih millis() dengan waktu awal itu dibandingkan dengan lama timer (menit × 60.000 ms). Setiap 5 detik sisa waktu dalam menit dikirim ke gauge.

Begitu waktu habis, buzzer berbunyi selama 10 detik dengan pola tiga bunyi pendek lalu jeda. Indikator SIAP menyala, dan switch Mulai dikembalikan ke posisi mati, jadi timer berikutnya tinggal dinyalakan lagi.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
Modul buzzer aktif KY-012	1	Rp7.500
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp53.000

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Modul buzzer aktif KY-012 S	→	D2 GPIO4	kuning
Modul buzzer aktif KY-012 +	→	3V	merah
Modul buzzer aktif KY-012 −	→	G	hitam

Langkah 2: Siapkan dashboard Klenik

Lama Masakichibot/budi1234/p060/menit

10 menit10 of 60 menit

0 detik lalu

Timerichibot/budi1234/p060/mulai

Mulai

0 detik lalu

Masakanichibot/budi1234/p060/selesai

SIAP!

0 detik lalu

Sisa Waktuichibot/budi1234/p060/sisa

0 detik lalu

Catatanichibot/budi1234/p060/log

Timer 10 menit dimulai

Masakan siap!

0 detik lalu

Cara cepat: unduh p060.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Slider Output Lama Masak	`ichibot/KODE/p060/menit`	1–60 menit
Switch Timer	`ichibot/KODE/p060/mulai`	payload ON / OFF
Indikator Boolean Masakan	`ichibot/KODE/p060/selesai`	ON = `1` “SIAP!”, OFF = `0`
Gauge Sisa Waktu	`ichibot/KODE/p060/sisa`	0–60 mnt
Text Log Catatan	`ichibot/KODE/p060/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p060.inoUnduh .ino

// Proyek 060 - Timer Masak dengan Bunyi
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_MULAI   = "ichibot/budi1234/p060/mulai";
const char* TOPIK_SISA    = "ichibot/budi1234/p060/sisa";
const char* TOPIK_SELESAI = "ichibot/budi1234/p060/selesai";
const char* TOPIK_LOG     = "ichibot/budi1234/p060/log";
const char* TOPIK_MENIT   = "ichibot/budi1234/p060/menit";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int BUZZER = D2;
int menit = 10;                       // lama timer dari slider
bool jalan = false;
unsigned long mulai = 0, kirimTerakhir = 0, bunyiSampai = 0;

void berhenti() {
  jalan = false;
  mqtt.publish(TOPIK_MULAI, "OFF", true);
  mqtt.publish(TOPIK_SISA, "0");
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_MENIT) {
    menit = p.toInt();
  } else if (topik == TOPIK_MULAI) {
    if (p == "ON" && !jalan) {
      jalan = true;
      mulai = millis();
      bunyiSampai = 0;
      mqtt.publish(TOPIK_SELESAI, "0");
      mqtt.publish(TOPIK_LOG, ("Timer " + String(menit) + " menit dimulai").c_str());
    } else if (p == "OFF" && jalan) {
      berhenti();
      mqtt.publish(TOPIK_LOG, "Timer dibatalkan");
    }
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_MENIT);
  mqtt.subscribe(TOPIK_MULAI);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(BUZZER, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (jalan) {
    unsigned long lama = (unsigned long)menit * 60000UL;
    unsigned long lewat = millis() - mulai;
    if (lewat >= lama) {
      berhenti();
      bunyiSampai = millis() + 10000;   // bunyi 10 detik
      mqtt.publish(TOPIK_SELESAI, "1");
      mqtt.publish(TOPIK_LOG, "Masakan siap!");
    } else if (millis() - kirimTerakhir >= 5000) {
      kirimTerakhir = millis();
      float sisa = (lama - lewat) / 60000.0;
      mqtt.publish(TOPIK_SISA, String(sisa, 1).c_str());
    }
  }

  if (bunyiSampai) {                  // pola tit-tit-tit ... jeda
    digitalWrite(BUZZER, (millis() % 1000) < 600 && (millis() % 200) < 100);
    if ((long)(millis() - bunyiSampai) >= 0) {
      bunyiSampai = 0;
      digitalWrite(BUZZER, LOW);
    }
  }
}

// Proyek 060 - Timer Masak dengan Bunyi
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_MULAI   = "ichibot/budi1234/p060/mulai";
const char* TOPIK_SISA    = "ichibot/budi1234/p060/sisa";
const char* TOPIK_SELESAI = "ichibot/budi1234/p060/selesai";
const char* TOPIK_LOG     = "ichibot/budi1234/p060/log";
const char* TOPIK_MENIT   = "ichibot/budi1234/p060/menit";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int BUZZER = D2;
int menit = 10;                       // lama timer dari slider
bool jalan = false;
unsigned long mulai = 0, kirimTerakhir = 0, bunyiSampai = 0;

void berhenti() {
  jalan = false;
  mqtt.publish(TOPIK_MULAI, "OFF", true);
  mqtt.publish(TOPIK_SISA, "0");
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_MENIT) {
    menit = p.toInt();
  } else if (topik == TOPIK_MULAI) {
    if (p == "ON" && !jalan) {
      jalan = true;
      mulai = millis();
      bunyiSampai = 0;
      mqtt.publish(TOPIK_SELESAI, "0");
      mqtt.publish(TOPIK_LOG, ("Timer " + String(menit) + " menit dimulai").c_str());
    } else if (p == "OFF" && jalan) {
      berhenti();
      mqtt.publish(TOPIK_LOG, "Timer dibatalkan");
    }
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_MENIT);
  mqtt.subscribe(TOPIK_MULAI);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(BUZZER, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

if (jalan) {
    unsigned long lama = (unsigned long)menit * 60000UL;
    unsigned long lewat = millis() - mulai;
    if (lewat >= lama) {
      berhenti();
      bunyiSampai = millis() + 10000;   // bunyi 10 detik
      mqtt.publish(TOPIK_SELESAI, "1");
      mqtt.publish(TOPIK_LOG, "Masakan siap!");
    } else if (millis() - kirimTerakhir >= 5000) {
      kirimTerakhir = millis();
      float sisa = (lama - lewat) / 60000.0;
      mqtt.publish(TOPIK_SISA, String(sisa, 1).c_str());
    }
  }

if (bunyiSampai) {                  // pola tit-tit-tit ... jeda
    digitalWrite(BUZZER, (millis() % 1000) < 600 && (millis() % 200) < 100);
    if ((long)(millis() - bunyiSampai) >= 0) {
      bunyiSampai = 0;
      digitalWrite(BUZZER, LOW);
    }
  }
}

Langkah 4: Pahami kodenya

Menit diubah ke milidetik. Hasilnya bisa jutaan, jadi dipaksa ke unsigned long sebelum dikalikan supaya tidak meluap.
Sisa waktu dalam menit dengan satu angka desimal. Pembagi 60000.0 (ada titiknya) membuat hasil bagi berupa pecahan, bukan bilangan bulat.
Pola tanpa delay(). Dalam tiap 1 detik, 600 ms pertama diisi bunyi 100 ms nyala dan 100 ms mati (3 bunyi), lalu 400 ms diam.
Switch Mulai di dashboard dikembalikan ke OFF. Pesan ini juga kembali ke NodeMCU, tetapi diabaikan karena timer sudah tidak jalan (jalan = false).