Bel berbunyi 5 detik pada jam masuk, istirahat, dan pulang. Jadwalnya ditulis di Klenik sebagai daftar jam, misalnya 07:00,09:30,12:00, dan bisa diganti kapan saja tanpa upload ulang. Hari Minggu bel diam.

NodeMCU mengambil jam dari internet (NTP) seperti proyek 020, jadi tidak perlu modul RTC. Setiap kali menit berganti, jam sekarang dalam bentuk HH:MM dicari di daftar jadwal. Kalau ada, buzzer dinyalakan 5 detik.

Daftar jadwal dikirim dari widget Text Input. Setelah diterima, NodeMCU mengirimnya kembali ke topic yang sama dengan flag retained. Broker menyimpan salinan terakhir, sehingga NodeMCU yang mati lampu lalu menyala lagi langsung menerima jadwal terbaru begitu tersambung.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
Modul buzzer aktif KY-012	1	Rp7.500
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp53.000

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Modul buzzer aktif KY-012 S	→	D2 GPIO4	kuning
Modul buzzer aktif KY-012 +	→	3V	merah
Modul buzzer aktif KY-012 −	→	G	hitam

Langkah 2: Siapkan dashboard Klenik

Jadwal Belichibot/budi1234/p057/jadwal

07:00,09:30,09:45,12:00,13:30

Belum pernah dikirim

Tes Belichibot/budi1234/p057/tes

Bunyikan

0 detik lalu

Riwayat Belichibot/budi1234/p057/log

Jadwal baru: 07:00,09:30,09:45,12:00,13:30

Bel 07:00

Bel 09:30

0 detik lalu

Cara cepat: unduh p057.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
TEXT_INPUT Jadwal Bel	`ichibot/KODE/p057/jadwal`	teks bebas
Switch Tes Bel	`ichibot/KODE/p057/tes`	payload ON / OFF
Text Log Riwayat Bel	`ichibot/KODE/p057/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p057.inoUnduh .ino

// Proyek 057 - Bel Sekolah Terjadwal
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_JADWAL = "ichibot/budi1234/p057/jadwal";
const char* TOPIK_LOG    = "ichibot/budi1234/p057/log";
const char* TOPIK_TES    = "ichibot/budi1234/p057/tes";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int BUZZER = D2;
String jadwal = "07:00,09:30,09:45,12:00,13:30";   // diganti dari dashboard
String menitTadi = "";
unsigned long bunyiSampai = 0;

void bunyi(unsigned long ms) {
  digitalWrite(BUZZER, HIGH);
  bunyiSampai = millis() + ms;
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  p.trim();
  if (topik == TOPIK_JADWAL && p.length() && p != jadwal) {
    jadwal = p;
    mqtt.publish(TOPIK_JADWAL, jadwal.c_str(), true);   // disimpan broker untuk restart berikutnya
    mqtt.publish(TOPIK_LOG, ("Jadwal baru: " + jadwal).c_str());
  } else if (topik == TOPIK_TES && p == "ON") {
    bunyi(3000);
    mqtt.publish(TOPIK_TES, "OFF");
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_JADWAL);
  mqtt.subscribe(TOPIK_TES);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(BUZZER, OUTPUT);
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");   // WIB = UTC+7
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  time_t t = time(nullptr);
  if (t > 1700000000) {               // jam sudah sinkron dari internet
    struct tm* w = localtime(&t);
    char jam[6];
    strftime(jam, sizeof(jam), "%H:%M", w);
    String menit = jam;
    if (menit != menitTadi) {
      menitTadi = menit;
      bool libur = (w->tm_wday == 0);   // Minggu
      if (!libur && ("," + jadwal + ",").indexOf("," + menit + ",") >= 0) {
        bunyi(5000);
        mqtt.publish(TOPIK_LOG, ("Bel " + menit).c_str());
      }
    }
  }
  if (bunyiSampai && (long)(millis() - bunyiSampai) >= 0) {
    bunyiSampai = 0;
    digitalWrite(BUZZER, LOW);
  }
}

// Proyek 057 - Bel Sekolah Terjadwal
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_JADWAL = "ichibot/budi1234/p057/jadwal";
const char* TOPIK_LOG    = "ichibot/budi1234/p057/log";
const char* TOPIK_TES    = "ichibot/budi1234/p057/tes";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int BUZZER = D2;
String jadwal = "07:00,09:30,09:45,12:00,13:30";   // diganti dari dashboard
String menitTadi = "";
unsigned long bunyiSampai = 0;

void bunyi(unsigned long ms) {
  digitalWrite(BUZZER, HIGH);
  bunyiSampai = millis() + ms;
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  p.trim();
  if (topik == TOPIK_JADWAL && p.length() && p != jadwal) {
    jadwal = p;
    mqtt.publish(TOPIK_JADWAL, jadwal.c_str(), true);   // disimpan broker untuk restart berikutnya
    mqtt.publish(TOPIK_LOG, ("Jadwal baru: " + jadwal).c_str());
  } else if (topik == TOPIK_TES && p == "ON") {
    bunyi(3000);
    mqtt.publish(TOPIK_TES, "OFF");
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_JADWAL);
  mqtt.subscribe(TOPIK_TES);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(BUZZER, OUTPUT);
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");   // WIB = UTC+7
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

time_t t = time(nullptr);
  if (t > 1700000000) {               // jam sudah sinkron dari internet
    struct tm* w = localtime(&t);
    char jam[6];
    strftime(jam, sizeof(jam), "%H:%M", w);
    String menit = jam;
    if (menit != menitTadi) {
      menitTadi = menit;
      bool libur = (w->tm_wday == 0);   // Minggu
      if (!libur && ("," + jadwal + ",").indexOf("," + menit + ",") >= 0) {
        bunyi(5000);
        mqtt.publish(TOPIK_LOG, ("Bel " + menit).c_str());
      }
    }
  }
  if (bunyiSampai && (long)(millis() - bunyiSampai) >= 0) {
    bunyiSampai = 0;
    digitalWrite(BUZZER, LOW);
  }
}

Langkah 4: Pahami kodenya

Jadwal awal sebelum ada kiriman dari dashboard. Tulis jam dua digit (07:00, bukan 7:00) dan pisahkan dengan koma tanpa spasi.
Jadwal disimpan di broker (retained). Syarat p != jadwal di atasnya mencegah putaran: pesan yang kembali ke kita sendiri sama isinya, jadi diabaikan.
Pengecekan hanya sekali tiap menit berganti. Tanpa ini, bel akan berbunyi berulang-ulang selama satu menit penuh.
Trik pencarian sederhana: jadwal diapit koma, lalu dicari ,07:00,. Jam 17:00 tidak ikut cocok saat mencari 07:00 karena ada koma di depannya.