Level Kebisingan Ruangan MAX4466

// Proyek 054 - Level Kebisingan Ruangan MAX4466
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_BATAS  = "ichibot/budi1234/p054/batas";
const char* TOPIK_LEVEL  = "ichibot/budi1234/p054/level";
const char* TOPIK_BISING = "ichibot/budi1234/p054/bising";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int MIC = 34;                   // ADC1, aman dipakai saat WiFi aktif
const int PUNCAK_PENUH = 2000;        // selisih puncak yang dianggap 100%
int batas = 60;                       // di atas ini dianggap bising (%)
long total = 0;
int jumlahUkur = 0;
unsigned long kirimTerakhir = 0;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  batas = p.toInt();
}

void langganan() {
  mqtt.subscribe(TOPIK_BATAS);
}

int ukurPuncak() {                    // selisih tertinggi-terendah dalam 50 ms
  int tinggi = 0, rendah = 4095;
  unsigned long mulai = millis();
  while (millis() - mulai < 50) {
    int v = analogRead(MIC);
    if (v > tinggi) tinggi = v;
    if (v < rendah) rendah = v;
  }
  return tinggi - rendah;
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  total += ukurPuncak();
  jumlahUkur++;
  if (millis() - kirimTerakhir >= 1000) {
    kirimTerakhir = millis();
    int rata = total / jumlahUkur;
    int level = constrain(map(rata, 0, PUNCAK_PENUH, 0, 100), 0, 100);
    total = 0;
    jumlahUkur = 0;
    Serial.println("Puncak rata-rata " + String(rata) + " -> " + String(level) + "%");
    mqtt.publish(TOPIK_LEVEL, String(level).c_str());
    mqtt.publish(TOPIK_BISING, level > batas ? "1" : "0");
  }
}