Bunyikan buzzer dari HP: nyala terus dengan switch, atau sejumlah bip dengan slider. Berguna untuk memanggil orang di ruangan lain atau mengetes alat sebelum dipasang.

Buzzer aktif sudah punya osilator di dalamnya, jadi cukup diberi HIGH untuk berbunyi. Switch mengatur nyala terus. Slider mengirim angka 1-10, lalu NodeMCU menjalankan pola bip: setiap 150 ms buzzer dibalik, sebanyak dua kali jumlah bip (nyala + mati). Selama pola berjalan, loop() tetap berputar dan perintah baru langsung diterima.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
Modul buzzer aktif KY-012	1	Rp7.500
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp53.000

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Modul buzzer aktif KY-012 S	→	D2 GPIO4	biru
Modul buzzer aktif KY-012 +	→	3V	merah
Modul buzzer aktif KY-012 −	→	G	hitam

Langkah 2: Siapkan dashboard Klenik

Buzzerichibot/budi1234/p051/buzzer

Bunyi terus

Belum pernah ditekan

Jumlah Bipichibot/budi1234/p051/bip

33 of 10

0 detik lalu

Cara cepat: unduh p051.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Switch Buzzer	`ichibot/KODE/p051/buzzer`	payload ON / OFF
Slider Output Jumlah Bip	`ichibot/KODE/p051/bip`	1–10

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p051.inoUnduh .ino

// Proyek 051 - Buzzer Dibunyikan dari HP
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_BUZZER = "ichibot/budi1234/p051/buzzer";
const char* TOPIK_BIP    = "ichibot/budi1234/p051/bip";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int BUZZER = D2;
int pola = 0;                         // sisa langkah pola bunyi
unsigned long langkahBerikut = 0;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t, p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_BUZZER) digitalWrite(BUZZER, p == "ON");   // switch: nyala terus / mati
  else if (topik == TOPIK_BIP) pola = constrain(p.toInt(), 1, 10) * 2;   // slider: jumlah bip
}

void langganan() {
  mqtt.subscribe(TOPIK_BUZZER);
  mqtt.subscribe(TOPIK_BIP);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(BUZZER, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (pola > 0 && millis() >= langkahBerikut) {
    digitalWrite(BUZZER, pola % 2 == 0);    // genap: bunyi, ganjil: diam
    pola--;
    langkahBerikut = millis() + 150;
  }
}

// Proyek 051 - Buzzer Dibunyikan dari HP
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_BUZZER = "ichibot/budi1234/p051/buzzer";
const char* TOPIK_BIP    = "ichibot/budi1234/p051/bip";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int BUZZER = D2;
int pola = 0;                         // sisa langkah pola bunyi
unsigned long langkahBerikut = 0;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t, p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_BUZZER) digitalWrite(BUZZER, p == "ON");   // switch: nyala terus / mati
  else if (topik == TOPIK_BIP) pola = constrain(p.toInt(), 1, 10) * 2;   // slider: jumlah bip
}

void langganan() {
  mqtt.subscribe(TOPIK_BUZZER);
  mqtt.subscribe(TOPIK_BIP);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(BUZZER, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (pola > 0 && millis() >= langkahBerikut) {
    digitalWrite(BUZZER, pola % 2 == 0);    // genap: bunyi, ganjil: diam
    pola--;
    langkahBerikut = millis() + 150;
  }
}

Langkah 4: Pahami kodenya

Tiga bip = 6 langkah: nyala, mati, nyala, mati, nyala, mati.
Langkah genap menyalakan, ganjil mematikan. Pola selalu berakhir dalam keadaan mati.