Tanaman tidak peduli seberapa terang ruangan sesaat, yang penting total cahaya sepanjang hari. Proyek ini menghitung DLI (Daily Light Integral), angka yang dipakai petani hidroponik untuk menentukan apakah tanaman perlu lampu tambahan.

Setiap menit, lux dari BH1750 diubah menjadi perkiraan PPFD (jumlah foton yang dipakai fotosintesis per detik). Untuk sinar matahari, 1 lux ≈ 0,0185 µmol/m²/s. PPFD dikali 60 detik lalu dijumlahkan sepanjang hari menjadi DLI dalam mol/m²/hari. Saat tanggal berganti (dari NTP), DLI kemarin disimpan dengan retain dan penghitung dimulai dari 0.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Sensor cahaya BH1750 (GY-30)	1	Rp19.400
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 4	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp97.900

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
BH1750 GY-30 (I2C) VCC	→	3V3	merah
BH1750 GY-30 (I2C) GND	→	GND	hitam
BH1750 GY-30 (I2C) SCL	→	D22 GPIO22	kuning
BH1750 GY-30 (I2C) SDA	→	D21 GPIO21	hijau

Langkah 2: Siapkan dashboard Klenik

DLI Hari Iniichibot/budi1234/p039/dli

0 detik lalu

DLI Kemarinichibot/budi1234/p039/kemarin

0 detik lalu

Cahayaichibot/budi1234/p039/lux

100lux

0.0lux10 titik5000.0lux

0 detik lalu

Cara cepat: unduh p039.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Gauge DLI Hari Ini	`ichibot/KODE/p039/dli`	0–30 mol
Gauge DLI Kemarin	`ichibot/KODE/p039/kemarin`	0–30 mol
Chart Cahaya	`ichibot/KODE/p039/lux`	0–5000 lux

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), BH1750 (Christopher Laws). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p039.inoUnduh .ino

// Proyek 039 - Monitor Cahaya untuk Tanaman Indoor
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <BH1750.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_KEMARIN = "ichibot/budi1234/p039/kemarin";
const char* TOPIK_LUX     = "ichibot/budi1234/p039/lux";
const char* TOPIK_DLI     = "ichibot/budi1234/p039/dli";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
BH1750 lux;
double dli = 0;                       // Daily Light Integral, mol/m²/hari
int hariTadi = -1;
unsigned long terakhir = 0;

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  Wire.begin();
  lux.begin();
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (millis() - terakhir < 60000) return;   // tiap menit
  terakhir = millis();

  time_t t = time(nullptr);
  int hari = localtime(&t)->tm_yday;
  if (hari != hariTadi) {                    // ganti hari: mulai hitung dari 0
    if (hariTadi >= 0) mqtt.publish(TOPIK_KEMARIN, String(dli, 1).c_str(), true);
    dli = 0;
    hariTadi = hari;
  }
  float lx = lux.readLightLevel();
  float ppfd = lx * 0.0185;                  // perkiraan untuk cahaya matahari (µmol/m²/s)
  dli += ppfd * 60 / 1e6;                    // 60 detik terakhir
  mqtt.publish(TOPIK_LUX, String(lx, 0).c_str());
  mqtt.publish(TOPIK_DLI, String(dli, 2).c_str());
}

// Proyek 039 - Monitor Cahaya untuk Tanaman Indoor
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <BH1750.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_KEMARIN = "ichibot/budi1234/p039/kemarin";
const char* TOPIK_LUX     = "ichibot/budi1234/p039/lux";
const char* TOPIK_DLI     = "ichibot/budi1234/p039/dli";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
BH1750 lux;
double dli = 0;                       // Daily Light Integral, mol/m²/hari
int hariTadi = -1;
unsigned long terakhir = 0;

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  Wire.begin();
  lux.begin();
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (millis() - terakhir < 60000) return;   // tiap menit
  terakhir = millis();

time_t t = time(nullptr);
  int hari = localtime(&t)->tm_yday;
  if (hari != hariTadi) {                    // ganti hari: mulai hitung dari 0
    if (hariTadi >= 0) mqtt.publish(TOPIK_KEMARIN, String(dli, 1).c_str(), true);
    dli = 0;
    hariTadi = hari;
  }
  float lx = lux.readLightLevel();
  float ppfd = lx * 0.0185;                  // perkiraan untuk cahaya matahari (µmol/m²/s)
  dli += ppfd * 60 / 1e6;                    // 60 detik terakhir
  mqtt.publish(TOPIK_LUX, String(lx, 0).c_str());
  mqtt.publish(TOPIK_DLI, String(dli, 2).c_str());
}

Langkah 4: Pahami kodenya

Faktor konversi untuk sinar matahari. Untuk lampu LED tanaman (grow light) faktornya berbeda, sekitar 0,015-0,02.
µmol × detik dibagi sejuta = mol. Setiap menit menambah sedikit, dan totalnya terlihat di sore hari.
Ganti hari dideteksi dari nomor hari dalam setahun (tm_yday). Pembacaan pertama setelah menyala hanya mengisi hariTadi.