Alat ukur terang cahaya dalam satuan lux, seperti lux meter yang dipakai teknisi K3. Cocok untuk mengecek apakah meja kerja, kelas, atau gudang sudah cukup terang.

BH1750 berisi fotodioda dan pengubah analog-digital, lalu mengirim hasilnya sudah dalam lux lewat I2C. Tidak ada kalibrasi seperti LDR. Rentangnya 1-65.535 lux: ruangan kantor ±300-500 lux, siang di luar bisa lebih dari 30.000 lux. Hasilnya dibandingkan dengan patokan pencahayaan SNI 6197, lalu saran singkatnya dikirim ke Text Log.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Sensor cahaya BH1750 (GY-30)	1	Rp19.400
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 4	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp97.900

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
BH1750 GY-30 (I2C) VCC	→	3V3	merah
BH1750 GY-30 (I2C) GND	→	GND	hitam
BH1750 GY-30 (I2C) SCL	→	D22 GPIO22	kuning
BH1750 GY-30 (I2C) SDA	→	D21 GPIO21	hijau

Langkah 2: Siapkan dashboard Klenik

Terang Cahayaichibot/budi1234/p033/lux

0 detik lalu

Saranichibot/budi1234/p033/saran

Cukup untuk ruang kelas

Bagus untuk kantor & membaca

0 detik lalu

Cara cepat: unduh p033.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Gauge Terang Cahaya	`ichibot/KODE/p033/lux`	0–2000 lux
Text Log Saran	`ichibot/KODE/p033/saran`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), BH1750 (Christopher Laws). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p033.inoUnduh .ino

// Proyek 033 - Lux Meter BH1750
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <BH1750.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LUX   = "ichibot/budi1234/p033/lux";
const char* TOPIK_SARAN = "ichibot/budi1234/p033/saran";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
BH1750 lux;                           // I2C: SDA D21, SCL D22
unsigned long terakhir = 0;

String saran(float lx) {              // patokan pencahayaan kerja (SNI 6197)
  if (lx < 100) return "Gelap";
  if (lx < 250) return "Cukup untuk lorong / gudang";
  if (lx < 500) return "Cukup untuk ruang kelas";
  if (lx < 1000) return "Bagus untuk kantor & membaca";
  return "Sangat terang (dekat jendela / luar ruang)";
}

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  Wire.begin();
  if (!lux.begin()) Serial.println("BH1750 tidak ditemukan, cek SDA/SCL");
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (millis() - terakhir < 2000) return;
  terakhir = millis();

  float lx = lux.readLightLevel();
  if (lx < 0) return;                 // -1 = gagal baca
  mqtt.publish(TOPIK_LUX, String(lx, 0).c_str());
  mqtt.publish(TOPIK_SARAN, saran(lx).c_str());
}

// Proyek 033 - Lux Meter BH1750
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <BH1750.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LUX   = "ichibot/budi1234/p033/lux";
const char* TOPIK_SARAN = "ichibot/budi1234/p033/saran";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
BH1750 lux;                           // I2C: SDA D21, SCL D22
unsigned long terakhir = 0;

String saran(float lx) {              // patokan pencahayaan kerja (SNI 6197)
  if (lx < 100) return "Gelap";
  if (lx < 250) return "Cukup untuk lorong / gudang";
  if (lx < 500) return "Cukup untuk ruang kelas";
  if (lx < 1000) return "Bagus untuk kantor & membaca";
  return "Sangat terang (dekat jendela / luar ruang)";
}

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  Wire.begin();
  if (!lux.begin()) Serial.println("BH1750 tidak ditemukan, cek SDA/SCL");
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (millis() - terakhir < 2000) return;
  terakhir = millis();

float lx = lux.readLightLevel();
  if (lx < 0) return;                 // -1 = gagal baca
  mqtt.publish(TOPIK_LUX, String(lx, 0).c_str());
  mqtt.publish(TOPIK_SARAN, saran(lx).c_str());
}

Langkah 4: Pahami kodenya

Objek sensor dengan alamat bawaan 0x23 (kaki ADDR dibiarkan kosong atau ke GND).
Batas-batas ini diambil dari standar pencahayaan ruang kerja. Ubah sesuai kebutuhan ruanganmu.
Library mengembalikan -1 kalau pembacaan gagal. Angka ini tidak dikirim.