Dashboard langsung memberi tahu kalau perangkat mati atau putus WiFi, tanpa perlu dicek ke lokasi. Ada juga kekuatan sinyal WiFi dan lama perangkat menyala. Pola ini bisa ditempel ke proyek lain mana pun.

MQTT punya fitur last will (wasiat). Saat tersambung, perangkat menitipkan pesan 0 ke broker untuk topic .../p010/online. Kalau perangkat tiba-tiba hilang (listrik padam, WiFi putus), broker sendiri yang mengirim pesan titipan itu, jadi indikator di dashboard berubah jadi OFFLINE. Begitu tersambung lagi, perangkat mengirim 1. Kedua pesan memakai retain, jadi dashboard yang baru dibuka langsung tahu statusnya.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
LED 5 mm hijau (isi 10)isi 10, terpakai 1	1	Rp2.850
Resistor 330 Ω (isi 10)isi 10, terpakai 1	1	Rp1.800
Breadboard mini 170 titik	1	Rp4.875
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 2	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp55.025

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
LED hijau + resistor 330 Ω +	→	D1 GPIO5	hijau
LED hijau + resistor 330 Ω −	→	G	hitam

Langkah 2: Siapkan dashboard Klenik

Perangkatichibot/budi1234/p010/online

ONLINE

0 detik lalu

Sinyal WiFiichibot/budi1234/p010/sinyal

0 detik lalu

Lama Menyalaichibot/budi1234/p010/nyala

0 detik lalu

Cara cepat: unduh p010.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Indikator Boolean Perangkat	`ichibot/KODE/p010/online`	ON = `1` “ONLINE”, OFF = `0`
Gauge Sinyal WiFi	`ichibot/KODE/p010/sinyal`	-100–-30 dBm
Gauge Lama Menyala	`ichibot/KODE/p010/nyala`	0–1440 menit

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p010.inoUnduh .ino

// Proyek 010 - Indikator Status Online Perangkat
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_ONLINE = "ichibot/budi1234/p010/online";
const char* TOPIK_SINYAL = "ichibot/budi1234/p010/sinyal";
const char* TOPIK_NYALA  = "ichibot/budi1234/p010/nyala";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int LED = D1;                   // berkedip pelan = online
unsigned long terakhir = 0;

void langganan() {
  mqtt.publish(TOPIK_ONLINE, "1", true);   // menimpa pesan "0" dari last will
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(LED, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

// versi sambungMQTT dengan last will: broker mengirim "0" sendiri kalau perangkat hilang
void sambungDenganWasiat() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str(), TOPIK_ONLINE, 0, true, "0")) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      delay(3000);
    }
  }
}

void loop() {
  if (!mqtt.connected()) sambungDenganWasiat();
  mqtt.loop();
  if (millis() - terakhir >= 10000) {
    terakhir = millis();
    mqtt.publish(TOPIK_SINYAL, String(WiFi.RSSI()).c_str());
    mqtt.publish(TOPIK_NYALA, String(millis() / 60000).c_str());
  }
  digitalWrite(LED, (millis() / 1000) % 2);
}

// Proyek 010 - Indikator Status Online Perangkat
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_ONLINE = "ichibot/budi1234/p010/online";
const char* TOPIK_SINYAL = "ichibot/budi1234/p010/sinyal";
const char* TOPIK_NYALA  = "ichibot/budi1234/p010/nyala";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int LED = D1;                   // berkedip pelan = online
unsigned long terakhir = 0;

void langganan() {
  mqtt.publish(TOPIK_ONLINE, "1", true);   // menimpa pesan "0" dari last will
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(LED, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

// versi sambungMQTT dengan last will: broker mengirim "0" sendiri kalau perangkat hilang
void sambungDenganWasiat() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str(), TOPIK_ONLINE, 0, true, "0")) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      delay(3000);
    }
  }
}

void loop() {
  if (!mqtt.connected()) sambungDenganWasiat();
  mqtt.loop();
  if (millis() - terakhir >= 10000) {
    terakhir = millis();
    mqtt.publish(TOPIK_SINYAL, String(WiFi.RSSI()).c_str());
    mqtt.publish(TOPIK_NYALA, String(millis() / 60000).c_str());
  }
  digitalWrite(LED, (millis() / 1000) % 2);
}

Langkah 4: Pahami kodenya

Begitu tersambung, status diubah jadi 1 dengan retain. Pesan ini menimpa 0 yang mungkin dikirim broker waktu perangkat terakhir kali hilang.
Bentuk lengkap connect(): setelah ID ada topic wasiat, QoS 0, retain true, dan isi wasiat 0. Fungsi ini menggantikan sambungMQTT() standar khusus di proyek ini.
RSSI adalah kekuatan sinyal WiFi dalam dBm. Makin dekat ke 0 makin bagus: -50 sangat kuat, -80 lemah, di bawah -90 sering putus.
LED berkedip sekali per detik selama program berjalan. Kalau LED diam, berarti program macet atau sedang menunggu WiFi.